[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, November 11, 2020 @ 21:50:28
  Author: felixonmars
Revision: 751256

addpkg: haskell-blaze-textual 0.2.1.0-1

Added:
  haskell-blaze-textual/
  haskell-blaze-textual/repos/
  haskell-blaze-textual/trunk/
  haskell-blaze-textual/trunk/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: haskell-blaze-textual/trunk/PKGBUILD
===================================================================
--- haskell-blaze-textual/trunk/PKGBUILD	                        (rev 0)
+++ haskell-blaze-textual/trunk/PKGBUILD	2020-11-11 21:50:28 UTC (rev 751256)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=blaze-textual
+pkgname=haskell-blaze-textual
+pkgver=0.2.1.0
+pkgrel=1
+pkgdesc="Fast rendering of common datatypes"
+url="http://github.com/bos/blaze-textual"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-double-conversion' 'haskell-test-framework'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('1042795ab0bab891c034c24a51bafecbb89870ccd28af39534ab3d9ae7f46c2d')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}