[arch-commits] Commit in gedit-plugins/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Evangelos Foutras foutrelis at archlinux.org
Thu Nov 12 17:05:19 UTC 2020


    Date: Thursday, November 12, 2020 @ 17:05:19
  Author: foutrelis
Revision: 400610

archrelease: copy trunk to staging-x86_64

Added:
  gedit-plugins/repos/staging-x86_64/
  gedit-plugins/repos/staging-x86_64/PKGBUILD
    (from rev 400609, gedit-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gedit-plugins/repos/staging-x86_64/PKGBUILD (from rev 400609, gedit-plugins/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-12 17:05:19 UTC (rev 400610)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Hugo Doria <hugo at archlinux.org>
+# Contributor: Sergej Chodarev <sergejx at centrum.sk>
+# Contributor: zhuqin <zhuqin83 at gmail.com>
+
+pkgname=gedit-plugins
+pkgver=3.38.0
+pkgrel=2
+pkgdesc="Collection of plugins for the gedit Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit/ShippedPlugins"
+arch=(x86_64)
+license=(GPL)
+depends=(gedit python-dbus python-cairo)
+makedepends=(vte3 libgit2-glib gucharmap gobject-introspection vala yelp-tools
+             appstream-glib git meson)
+optdepends=('gucharmap: for charmap plugin'
+            'vte3: for embedded terminal'
+            'libgit2-glib: for git plugin')
+_commit=ff08d2a02a6a1084a37ed736d7bf0328ebd9df31  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit-plugins.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  python -m compileall -d /usr "$pkgdir/usr"
+  python -O -m compileall -d /usr "$pkgdir/usr"
+}
+
+# vim:set ts=2 sw=2 et:


More information about the arch-commits mailing list