[arch-commits] Commit in gnucash/repos (2 files)

[Felix Yan]

    Date: Thursday, November 12, 2020 @ 17:05:48
  Author: felixonmars
Revision: 752237

archrelease: copy trunk to community-staging-x86_64

Added:
  gnucash/repos/community-staging-x86_64/
  gnucash/repos/community-staging-x86_64/PKGBUILD
    (from rev 752235, gnucash/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gnucash/repos/community-staging-x86_64/PKGBUILD (from rev 752235, gnucash/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-12 17:05:48 UTC (rev 752237)
@@ -0,0 +1,49 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Mark Schneider <queueRAM at gmail.com>
+
+pkgname=gnucash
+pkgver=4.2
+pkgrel=2
+pkgdesc='Personal and small-business financial-accounting application'
+arch=(x86_64)
+url='https://gnucash.org/'
+license=(GPL)
+depends=(aqbanking gwenhywfar boost-libs guile libdbi webkit2gtk)
+makedepends=(boost cmake gmock libdbi-drivers mariadb-libs postgresql-libs swig)
+optdepends=('gnucash-docs: documentation'
+            'libdbi-drivers: open and save data into SQL database'
+            'perl-date-manip: stock information lookups'
+            'perl-finance-quote: stock information lookups')
+options=(!emptydirs)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
+sha256sums=('56d8ab039ef7784303ca9eab14bfc20f593f7a3f9b682a8a7eac25906a0d1308')
+
+build() {
+  cd $pkgname-$pkgver
+
+  # Do not treat warnings as errors
+  sed -e 's|-Werror||g' -i CMakeLists.txt
+
+  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DWITH_PYTHON=ON \
+        -DCOMPILE_GSCHEMAS=OFF
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make -k check || : # 2 tests failed
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # Delete the gnucash-valgrind executable because the source files
+  # are not included with the package and the executable is hardlinked
+  # to the location that it was built at.
+  rm -f "$pkgdir/usr/bin/gnucash-valgrind"
+}