[arch-commits] Commit in accerciser/repos (staging-any staging-any/PKGBUILD)

[Evangelos Foutras]

    Date: Thursday, November 12, 2020 @ 17:14:38
  Author: foutrelis
Revision: 400621

archrelease: copy trunk to staging-any

Added:
  accerciser/repos/staging-any/
  accerciser/repos/staging-any/PKGBUILD
    (from rev 400620, accerciser/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: accerciser/repos/staging-any/PKGBUILD (from rev 400620, accerciser/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2020-11-12 17:14:38 UTC (rev 400621)
@@ -0,0 +1,40 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Steve Holmes <steve.holmes88 at gmail.com>
+# Contributor: Giulio Bai <giulio at hewle.com>
+
+pkgname=accerciser
+pkgver=3.38.0
+pkgrel=2
+pkgdesc="Interactive Python accessibility explorer for the GNOME desktop"
+arch=(any)
+url="https://wiki.gnome.org/Apps/Accerciser"
+license=(BSD)
+depends=(python gtk3 python-atspi ipython libwnck3 python-cairo python-xlib)
+makedepends=(appstream-glib yelp-tools git)
+groups=(gnome-extra)
+_commit=d7f921335d930e0a0aa4d3fb5d1e25bc43b255d5  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/accerciser.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}