[arch-commits] Commit in kismet/repos (5 files)

Thu Nov 12 17:15:51 UTC 2020

Date: Thursday, November 12, 2020 @ 17:15:51
  Author: foutrelis
Revision: 400626

archrelease: copy trunk to staging-x86_64

Added:
  kismet/repos/staging-x86_64/
  kismet/repos/staging-x86_64/PKGBUILD
    (from rev 400625, kismet/trunk/PKGBUILD)
  kismet/repos/staging-x86_64/kismet.install
    (from rev 400625, kismet/trunk/kismet.install)
  kismet/repos/staging-x86_64/kismet.sysusers
    (from rev 400625, kismet/trunk/kismet.sysusers)
  kismet/repos/staging-x86_64/python-install-flags.patch
    (from rev 400625, kismet/trunk/python-install-flags.patch)

----------------------------+
 PKGBUILD                   |   72 +++++++++++++++++++++++++++++++++++++++++++
 kismet.install             |   19 +++++++++++
 kismet.sysusers            |    1 
 python-install-flags.patch |   45 ++++++++++++++++++++++++++
 4 files changed, 137 insertions(+)

Copied: kismet/repos/staging-x86_64/PKGBUILD (from rev 400625, kismet/trunk/PKGBUILD)
===================================================================

--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-12 17:15:51 UTC (rev 400626)
@@ -0,0 +1,72 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Jason Chu <jason at archlinux.org>
+
+pkgname=kismet
+pkgver=2020_09_R4
+_realver="${pkgver//_/-}"
+pkgrel=2
+pkgdesc="802.11 layer2 wireless network detector, sniffer, and intrusion detection system"
+url="https://www.kismetwireless.net/"
+arch=('x86_64')
+license=('GPL')
+depends=('libpcap' 'pcre' 'bluez-libs' 'libcap' 'libmicrohttpd' 'protobuf-c' 'libprotobuf-c.so'
+         'sqlite' 'libnm' 'gcc-libs' 'libusb' 'libusb-1.0.so' 'libnl' 'glibc' 'zlib' 'libelf'
+         'lm_sensors' 'systemd' 'python' 'python-setuptools' 'python-protobuf' 'python-pyserial'
+         'python-numpy')
+makedepends=('python-setuptools')
+optdepends=(
+  'gpsd: log coordinates of detected networks'
+  'wireshark-cli: provide OUI files used to determine device manufacturer'
+  'wireshark-cli: mergecap, to merge multiple capture files'
+  'sox: provide the default kismet sound playback binary'
+  'festival: text-to-speech support'
+  'flite:  alternative/lightweight text-to-speech support')
+backup=(
+  etc/kismet/kismet.conf
+  etc/kismet/kismet_80211.conf
+  etc/kismet/kismet_alerts.conf
+  etc/kismet/kismet_filter.conf
+  etc/kismet/kismet_httpd.conf
+  etc/kismet/kismet_logging.conf
+  etc/kismet/kismet_memory.conf
+  etc/kismet/kismet_storage.conf
+  etc/kismet/kismet_uav.conf)
+install=kismet.install
+source=(https://www.kismetwireless.net/code/${pkgname}-${_realver}.tar.xz
+        kismet.sysusers
+        python-install-flags.patch)
+sha512sums=('4f2dd641999dd2675d2c4dfbe28caf5a8476d5d7bd9dedeefb7b1420b48b9155a4d576123832974586d51c61ca4d77d8572ab7038da3ec6fa2a7791f3e1a1479'
+            '452b728c30c9932bdb91741af425267da87a66962ea9b736751948881f5477dee0bff8e2eeca2befdea2920da6d7d9e198bde69cef8c48bb49a0093a7f0ef897'
+            'c24bff8ecc0288c0584f60760a27b364bf7b013aad809e4050bb6ed703fc60f3ea93f7e897717a6924333ac6734b20b99166846dae4a9c5c303ae1de39f6692c')
+validpgpkeys=('354689DF3C9DED803381A661D7B28822738BBDB1') # Michael Kershaw
+
+prepare() {
+  cd ${pkgname}-${_realver}
+  patch -Np0 < ../python-install-flags.patch
+  autoreconf -fiv
+}
+
+build() {
+  cd ${pkgname}-${_realver}
+  ./configure \
+    --prefix=/usr \
+    --localstatedir=/var \
+    --sysconfdir=/etc/kismet
+  make all plugins
+}
+
+package() {
+  cd ${pkgname}-${_realver}
+  make DESTDIR="${pkgdir}" install
+
+  # Makepkg strip bug #43600
+  chmod u+w "${pkgdir}"/usr/bin/kismet*
+  chmod o-x "${pkgdir}"/usr/bin/kismet_cap*
+  chown 0:315 "${pkgdir}"/usr/bin/kismet_cap*
+
+  install -Dm 644 ../kismet.sysusers "${pkgdir}/usr/lib/sysusers.d/kismet.conf"
+}
+
+# vim: ts=2 sw=2 et:

Copied: kismet/repos/staging-x86_64/kismet.install (from rev 400625, kismet/trunk/kismet.install)
===================================================================
--- staging-x86_64/kismet.install	                        (rev 0)
+++ staging-x86_64/kismet.install	2020-11-12 17:15:51 UTC (rev 400626)
@@ -0,0 +1,19 @@
+post_install() {
+  post_upgrade
+
+  cat << EOP
+  Kismet has been installed with net_raw,net_admin capabilities capture helper
+  executables for users in the 'kismet' group. This WILL ALLOW USERS IN THIS
+  GROUP TO ALTER YOUR NETWORK INTERFACE STATES, but is more secure than running
+  all of Kismet as root. ONLY users in this group will be able to run Kismet
+  and capture from physical network devices.
+EOP
+}
+
+post_upgrade() {
+  for cap_bin in /usr/bin/kismet_cap_*; do
+    setcap cap_net_raw,cap_net_admin=eip "${cap_bin}";
+  done
+}
+
+# vim:set ts=2 sw=2 et:

Copied: kismet/repos/staging-x86_64/kismet.sysusers (from rev 400625, kismet/trunk/kismet.sysusers)
===================================================================
--- staging-x86_64/kismet.sysusers	                        (rev 0)
+++ staging-x86_64/kismet.sysusers	2020-11-12 17:15:51 UTC (rev 400626)
@@ -0,0 +1 @@
+g kismet 315 - - -

Copied: kismet/repos/staging-x86_64/python-install-flags.patch (from rev 400625, kismet/trunk/python-install-flags.patch)
===================================================================
--- staging-x86_64/python-install-flags.patch	                        (rev 0)
+++ staging-x86_64/python-install-flags.patch	2020-11-12 17:15:51 UTC (rev 400626)
@@ -0,0 +1,45 @@
+--- capture_freaklabs_zigbee/Makefile.in	2019-10-10 10:49:00.494256269 +0200
++++ capture_freaklabs_zigbee/Makefile.in	2019-10-10 10:52:49.374152190 +0200
+@@ -10,7 +10,7 @@
+ 	sed -i -E 's/^import kismet_/from . import kismet_/' $@
+ 
+ install:
+-	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)"
++	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)" -O1
+
+ clean:
+ 	@-$(PYTHON) setup.py clean
+--- capture_sdr_rtl433/Makefile.in	2019-10-10 10:49:00.507590313 +0200
++++ capture_sdr_rtl433/Makefile.in	2019-10-10 10:52:28.069331801 +0200
+@@ -11,7 +11,7 @@
+ 	sed -i -E 's/^import kismet_/from . import kismet_/' $@
+ 
+ install:
+-	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)"
++	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)" -O1
+
+ clean:
+ 	@-$(PYTHON) setup.py clean
+--- capture_sdr_rtladsb/Makefile.in	2019-10-10 10:49:00.510923825 +0200
++++ capture_sdr_rtladsb/Makefile.in	2019-10-10 10:52:32.542260533 +0200
+@@ -11,7 +11,7 @@
+ 	sed -i -E 's/^import kismet_/from . import kismet_/' $@
+ 
+ install:
+-	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)"
++	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)" -O1
+
+ clean:
+ 	@-$(PYTHON) setup.py clean
+--- capture_sdr_rtlamr/Makefile.in	2019-10-10 10:49:00.514257335 +0200
++++ capture_sdr_rtlamr/Makefile.in	2019-10-10 10:52:35.978622527 +0200
+@@ -11,7 +11,7 @@
+ 	sed -i -E 's/^import kismet_/from . import kismet_/' $@
+ 
+ install:
+-	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)"
++	$(PYTHON) setup.py install --root="/$(DESTDIR)" --prefix="$(prefix)" -O1
+
+ clean:
+ 	@-$(PYTHON) setup.py clean
+

