[arch-commits] Commit in rhythmbox/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Thursday, November 12, 2020 @ 17:51:58
  Author: felixonmars
Revision: 400653

archrelease: copy trunk to staging-x86_64

Added:
  rhythmbox/repos/staging-x86_64/
  rhythmbox/repos/staging-x86_64/PKGBUILD
    (from rev 400652, rhythmbox/trunk/PKGBUILD)

----------+
 PKGBUILD |   75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

Copied: rhythmbox/repos/staging-x86_64/PKGBUILD (from rev 400652, rhythmbox/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-12 17:51:58 UTC (rev 400653)
@@ -0,0 +1,75 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+
+pkgname=rhythmbox
+pkgver=3.4.4
+pkgrel=2
+pkgdesc="Music playback and management application"
+arch=(x86_64)
+license=(GPL)
+url="https://wiki.gnome.org/Apps/Rhythmbox"
+depends=(dconf gst-plugins-base gst-plugins-good libsoup json-glib libnotify libpeas
+         media-player-info totem-plparser tdb python-gobject libgudev grilo)
+makedepends=(itstool intltool brasero gobject-introspection vala grilo libdmapsharing lirc libgpod
+             libmtp gtk-doc yelp-tools git)
+checkdepends=(check xorg-server-xvfb)
+optdepends=('gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs'
+            'brasero: Audio CD Recorder plugin'
+            'libdmapsharing: DAAP Music Sharing plugin'
+            'grilo-plugins: Grilo media browser plugin'
+            'lirc: LIRC plugin'
+            'libgpod: Portable Players - iPod plugin'
+            'libmtp: Portable Players - MTP plugin'
+            'gvfs-mtp: Portable Players - Android plugin')
+_commit=473a28752bfd6260d74f41e3b0d737f71495f4a8  # tags/v3.4.4^0
+source=("git+https://gitlab.gnome.org/GNOME/rhythmbox.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/rhythmbox \
+    --disable-browser-plugin \
+    --disable-static \
+    --disable-more-warnings \
+    --enable-daap \
+    --enable-gtk-doc \
+    --enable-python \
+    --enable-vala \
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  glib-compile-schemas --targetdir=tests --schema-file=data/org.gnome.rhythmbox.gschema.xml
+  GSETTINGS_BACKEND=memory \
+  GSETTINGS_SCHEMA_DIR="$PWD/tests" \
+  CK_TIMEOUT_MULTIPLIER=3 \
+  xvfb-run -a -n 63 make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/lib/rhythmbox/sample-plugins"
+  rm -r "$pkgdir/usr/lib/rhythmbox/plugins/rbzeitgeist"
+}