[arch-commits] Commit in cantor/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Thursday, November 12, 2020 @ 18:45:16
  Author: foutrelis
Revision: 400674

archrelease: copy trunk to staging-x86_64

Added:
  cantor/repos/staging-x86_64/
  cantor/repos/staging-x86_64/PKGBUILD
    (from rev 400672, cantor/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: cantor/repos/staging-x86_64/PKGBUILD (from rev 400672, cantor/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-12 18:45:16 UTC (rev 400674)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=cantor
+pkgver=20.08.3
+pkgrel=2
+pkgdesc="KDE Frontend to Mathematical Software"
+url="https://kde.org/applications/education/cantor/"
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kde-education)
+depends=(analitza libspectre kpty ktexteditor knewstuff libqalculate hicolor-icon-theme qt5-xmlpatterns poppler-qt5)
+makedepends=(extra-cmake-modules python kdoctools luajit r julia)
+optdepends=('maxima: Maxima backend'
+            'octave: Octave backend'
+            'r: R backend'
+            'luajit: LUA backend'
+            'python: Python backend'
+            'sagemath: SageMath backend'
+            'julia: Julia backend')
+source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('14aefe60ca2ff7aeaf7af8080dd00e80be8d747faeb9cd5a2df88f0d3af358da'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}