[arch-commits] Commit in python-pyotp/repos (2 files)

[Evangelos Foutras]

    Date: Thursday, November 12, 2020 @ 19:12:13
  Author: foutrelis
Revision: 753366

archrelease: copy trunk to community-staging-any

Added:
  python-pyotp/repos/community-staging-any/
  python-pyotp/repos/community-staging-any/PKGBUILD
    (from rev 753365, python-pyotp/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-pyotp/repos/community-staging-any/PKGBUILD (from rev 753365, python-pyotp/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-12 19:12:13 UTC (rev 753366)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: ELmoussaoui Bilal <bil.elmoussaoui at gmail.com>
+
+pkgname=python-pyotp
+_pkgname=pyotp
+_gitcommit=041f5d3c65379d7188821caf92436c7f226ec60e
+pkgver=2.3.0
+pkgrel=3
+pkgdesc='Python library for generating and verifying one-time passwords'
+url='https://pyotp.readthedocs.io/'
+arch=('any')
+license=('MIT')
+depends=('python')
+makedepends=('git' 'python-setuptools' 'python-sphinx')
+options=('!makeflags')
+source=("git+https://github.com/pyotp/pyotp#commit=${_gitcommit}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('29BCBADB4ECAAAC2382699388AFAFCD242818A52') # Andrey Kislyuk <kislyuk at gmail.com>
+
+pkgver() {
+  cd ${_pkgname}
+  git describe --always --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd ${_pkgname}
+  python setup.py build
+  make -C docs text man
+}
+
+check() {
+  cd ${_pkgname}
+  python setup.py test
+}
+
+package() {
+  cd ${_pkgname}
+  python setup.py install --root="${pkgdir}" -O1 --skip-build
+  install -Dm 644 README.rst ./docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 ./docs/_build/man/${_pkgname}.1 -t "${pkgdir}/usr/share/man/man1"
+  ln -s /usr/share/man/man1/${_pkgname}.1.gz "${pkgdir}/usr/share/man/man1/${pkgname}.1.gz"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: