[arch-commits] Commit in python-pyopencl/repos (3 files)

Evangelos Foutras foutrelis at archlinux.org
Thu Nov 12 19:50:05 UTC 2020


    Date: Thursday, November 12, 2020 @ 19:50:05
  Author: foutrelis
Revision: 753643

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pyopencl/repos/community-staging-x86_64/
  python-pyopencl/repos/community-staging-x86_64/LICENSE.txt
    (from rev 753641, python-pyopencl/trunk/LICENSE.txt)
  python-pyopencl/repos/community-staging-x86_64/PKGBUILD
    (from rev 753641, python-pyopencl/trunk/PKGBUILD)

-------------+
 LICENSE.txt |   20 ++++++++++++++++++++
 PKGBUILD    |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

Copied: python-pyopencl/repos/community-staging-x86_64/LICENSE.txt (from rev 753641, python-pyopencl/trunk/LICENSE.txt)
===================================================================
--- community-staging-x86_64/LICENSE.txt	                        (rev 0)
+++ community-staging-x86_64/LICENSE.txt	2020-11-12 19:50:05 UTC (rev 753643)
@@ -0,0 +1,20 @@
+Permission is hereby granted, free of charge, to any person
+obtaining a copy of this software and associated documentation
+files (the "Software"), to deal in the Software without
+restriction, including without limitation the rights to use,
+copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the
+Software is furnished to do so, subject to the following
+conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
+OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
+HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
+WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+OTHER DEALINGS IN THE SOFTWARE.

Copied: python-pyopencl/repos/community-staging-x86_64/PKGBUILD (from rev 753641, python-pyopencl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-12 19:50:05 UTC (rev 753643)
@@ -0,0 +1,53 @@
+# Maintianer: Santiago Torres-Arias <santiago at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+
+_pypiname=pyopencl
+pkgbase=python-pyopencl
+pkgname=('python-pyopencl' 'pyopencl-headers')
+pkgver=2020.2.1
+pkgrel=2
+epoch=1
+pkgdesc="A complete, object-oriented language binding of OpenCL to Python"
+arch=('x86_64')
+url="https://mathema.tician.de/software/pyopencl"
+license=('MIT' 'Apache' 'BSD')
+depends=('opencl-icd-loader' 'opencl-headers' 'mesa' 'boost-libs')
+makedepends=('ctags' 'python-setuptools' 'python-mako' 'python-numpy' 'git'
+             'pybind11')
+checkdepends=('python-six' 'python-appdirs' 'python-pytest' 'python-pytools')
+source=("git+https://github.com/inducer/pyopencl.git?signed#tag=v${pkgver}")
+validpgpkeys=("900A958D9A0ACA58B1468F2471AA298BCA171145") # Andreas Ratchke
+sha1sums=('SKIP')
+
+build() {
+    cd "pyopencl"
+    git submodule init && git submodule update
+    python3 ./configure.py --python-exe=python3 --cl-pretend-version=1.2 # --boost-python-libname=boost_python3
+    make
+}
+
+check(){
+    # INFO: to avoid a PLATFORM_NOT_FOUND_KHR error here, you would have to install
+    # the driver of your specific video card in here
+    # checkdepends+=('amdgpu')
+    cd pyopencl
+    PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.9/" make tests
+}
+
+package_python-pyopencl() {
+    depends+=('python' 'python-numpy' 'python-mako' 'python-pytools' 'pyopencl-headers' 'python-setuptools' 'python-cffi')
+
+    cd pyopencl
+    python3 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+
+    rm -fr "${pkgdir}"/usr/include
+
+    install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_pyopencl-headers() {
+    cd pyopencl
+ 
+    install -Dm644 pyopencl/cl/*.cl -t "${pkgdir}"/usr/include/pyopencl 
+    install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}



More information about the arch-commits mailing list