[arch-commits] Commit in tpm2-pkcs11/repos (2 files)

[Felix Yan]

    Date: Thursday, November 12, 2020 @ 19:52:04
  Author: felixonmars
Revision: 753662

archrelease: copy trunk to community-staging-x86_64

Added:
  tpm2-pkcs11/repos/community-staging-x86_64/
  tpm2-pkcs11/repos/community-staging-x86_64/PKGBUILD
    (from rev 753660, tpm2-pkcs11/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: tpm2-pkcs11/repos/community-staging-x86_64/PKGBUILD (from rev 753660, tpm2-pkcs11/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-12 19:52:04 UTC (rev 753662)
@@ -0,0 +1,39 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=tpm2-pkcs11
+pkgver=1.4.0
+pkgrel=3
+pkgdesc='PKCS#11 interface for Trusted Platform Module 2.0 hardware'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-pkcs11'
+license=('BSD')
+depends=('libyaml' 'openssl' 'python' 'python-cryptography' 'python-pyasn1-modules' 'python-yaml' 'sqlite'
+         'tpm2-tools' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-tctildr.so')
+makedepends=('cmocka')
+checkdepends=('expect' 'ibm-sw-tpm2' 'iproute2' 'java-hamcrest' 'junit'
+              'libp11' 'opensc' 'tpm2-abrmd' 'tpm2-tss-engine' 'wget' 'xxd')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('b271500c7aab256edf4b9e070e700bbc8162db070cd8dfe49289db60d8c4527b8e54c794beb8c97fda0d989e095ac6cb790898912993db1906b7139942c87ffb'
+            'SKIP')
+validpgpkeys=('5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	export CLASSPATH="/usr/share/java/junit.jar:/usr/share/java/hamcrest-core.jar:$CLASSPATH"
+	./configure --prefix=/usr --enable-unit $( ((CHECKFUNC)) && echo --enable-integration)
+	make
+	cd tools
+	python setup.py build
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+	cd tools
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}