[arch-commits] Commit in python-gitpython/repos (2 files)

[Evangelos Foutras]

    Date: Thursday, November 12, 2020 @ 20:07:22
  Author: foutrelis
Revision: 753696

archrelease: copy trunk to community-staging-any

Added:
  python-gitpython/repos/community-staging-any/
  python-gitpython/repos/community-staging-any/PKGBUILD
    (from rev 753695, python-gitpython/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-gitpython/repos/community-staging-any/PKGBUILD (from rev 753695, python-gitpython/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-12 20:07:22 UTC (rev 753696)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
+# Contributor: brent s. <bts[at]square-r00t[dot]net>
+
+_name=gitpython
+pkgdesc="A python library used to interact with Git repositories"
+pkgname=python-gitpython
+pkgver=3.1.11
+pkgrel=2
+url="https://github.com/gitpython-developers/gitpython"
+license=('BSD')
+arch=('any')
+depends=('git' 'python-gitdb')
+makedepends=('python-setuptools')
+checkdepends=('python-ddt' 'python-nose' 'python-pytest' 'python-virtualenv')
+source=("git+https://github.com/gitpython-developers/gitpython.git#tag=${pkgver}?signed")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+validpgpkeys=('27C50E7F590947D7273A741E85194C08421980C9') # Sebastian Thiel (In Rust I trust!) <byronimo at gmail.com>
+
+build() {
+  cd "${_name}"
+  python setup.py build
+}
+
+check() {
+  cd "${_name}"
+  export TRAVIS="VERY CONVENIENT"
+  git config --global user.name "Test User"
+  git config --global user.email "test at user.org"
+  ./init-tests-after-clone.sh
+  PYTHONDONTWRITEBYTECODE=1 pytest -v -k 'not test_reading and not test_writing and not test_base'
+}
+
+package() {
+  cd "${_name}"
+  export PYTHONHASHSEED=0
+  python setup.py install --skip-build \
+                          --optimize=1 \
+                          --root="${pkgdir}"
+  install -vDm 644 {AUTHORS,CHANGES,{CONTRIBUTING,README}.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+}