[arch-commits] Commit in python-fastapi/repos (2 files)

[Felix Yan]

    Date: Thursday, November 12, 2020 @ 20:45:56
  Author: felixonmars
Revision: 753754

archrelease: copy trunk to community-staging-any

Added:
  python-fastapi/repos/community-staging-any/
  python-fastapi/repos/community-staging-any/PKGBUILD
    (from rev 753753, python-fastapi/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-fastapi/repos/community-staging-any/PKGBUILD (from rev 753753, python-fastapi/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-12 20:45:56 UTC (rev 753754)
@@ -0,0 +1,55 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+_pkgname=fastapi
+pkgname=python-$_pkgname
+pkgver=0.61.2
+pkgrel=2
+pkgdesc='FastAPI framework, high performance, easy to learn, fast to code, ready for production'
+arch=('any')
+url='https://github.com/tiangolo/fastapi'
+license=('MIT')
+depends=('python-starlette' 'python-pydantic')
+optdepends=('python-requests' 'python-aiofiles' 'python-jinja' 'python-itsdangerous'
+            'python-yaml' 'python-graphene' 'python-ujson' 'python-orjson'
+            'python-email-validator' 'python-python-multipart')
+makedepends=('python-setuptools' 'python-dephell')
+checkdepends=('python-pytest-runner' 'python-pytest-cov' 'mypy'
+              'python-requests' 'python-aiofiles' 'python-jinja' 'python-itsdangerous'
+              'python-yaml' 'python-graphene' 'python-ujson' 'python-orjson'
+              'python-email-validator'  'python-pyjwt' 'python-sqlalchemy'
+              'python-peewee' 'python-flask' 'python-passlib'
+              'python-bcrypt' 'python-httpx' 'python-python-multipart'
+              'python-databases' 'python-aiosqlite' 'python-jose')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('87a641aa07a85b4787399c4c2497ffacdee1dd3462171a228b756a36d9cdd13335d204628b47357c22b35fa7467f671b00db741f6b681a395e6174704e1f8f25')
+
+prepare() {
+  cd $_pkgname-$pkgver
+
+  dephell deps convert --from pyproject.toml --to setup.py
+
+  # don't pin starlette dependency
+  sed -i 's|starlette.*"|starlette"|' pyproject.toml
+}
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  python setup.py pytest
+
+  mypy -p fastapi
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}