[arch-commits] Commit in (4 files)

[Antonio Rojas]

    Date: Friday, November 13, 2020 @ 17:39:07
  Author: arojas
Revision: 400757

community2extra: Moving partitionmanager from community to extra

Added:
  partitionmanager/
  partitionmanager/repos/
  partitionmanager/trunk/
  partitionmanager/trunk/PKGBUILD

----------+
 PKGBUILD |   27 +++++++++++++++++++++++++++
 1 file changed, 27 insertions(+)

Added: partitionmanager/trunk/PKGBUILD
===================================================================
--- partitionmanager/trunk/PKGBUILD	                        (rev 0)
+++ partitionmanager/trunk/PKGBUILD	2020-11-13 17:39:07 UTC (rev 400757)
@@ -0,0 +1,27 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+# Contributor: Nick B <Shirakawasuna at gmail _dot_com>
+
+pkgname=partitionmanager
+pkgver=4.2.0
+pkgrel=1
+pkgdesc="A KDE utility that allows you to manage disks, partitions, and file systems"
+arch=(x86_64)
+url="https://kde.org/applications/system/org.kde.partitionmanager"
+license=(GPL2)
+depends=(kpmcore hicolor-icon-theme kio)
+makedepends=(extra-cmake-modules kdoctools)
+source=("https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('e9096dd5ce3b11e93a4e45960734f2059609d637e1b70b02f57e6ae61e8884f8'
+            'SKIP')
+validpgpkeys=(1EE5A3205904BAA2B88C0A9D24FD31940095C0E1) # Andrius Štikonas <andrius at stikonas.eu>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}