[arch-commits] Commit in cantor/repos (2 files)

[Antonio Rojas]

    Date: Saturday, November 14, 2020 @ 00:08:26
  Author: arojas
Revision: 400840

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  cantor/repos/kde-unstable-x86_64/
  cantor/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 400839, cantor/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: cantor/repos/kde-unstable-x86_64/PKGBUILD (from rev 400839, cantor/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2020-11-14 00:08:26 UTC (rev 400840)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=cantor
+pkgver=20.11.80
+pkgrel=1
+pkgdesc="KDE Frontend to Mathematical Software"
+url="https://kde.org/applications/education/cantor/"
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kde-education)
+depends=(analitza libspectre kpty ktexteditor knewstuff libqalculate hicolor-icon-theme qt5-xmlpatterns poppler-qt5)
+makedepends=(extra-cmake-modules python kdoctools luajit r julia)
+optdepends=('maxima: Maxima backend'
+            'octave: Octave backend'
+            'r: R backend'
+            'luajit: LUA backend'
+            'python: Python backend'
+            'sagemath: SageMath backend'
+            'julia: Julia backend')
+source=("https://download.kde.org/unstable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('b8d1b2e41c28a54848b3de4cc1f4778b4491fe761435cfd86754504b0d1eb3ea'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}