[arch-commits] Commit in ktorrent/repos (2 files)

[Antonio Rojas]

    Date: Saturday, November 14, 2020 @ 00:23:09
  Author: arojas
Revision: 400930

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  ktorrent/repos/kde-unstable-x86_64/
  ktorrent/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 400929, ktorrent/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Copied: ktorrent/repos/kde-unstable-x86_64/PKGBUILD (from rev 400929, ktorrent/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2020-11-14 00:23:09 UTC (rev 400930)
@@ -0,0 +1,31 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Travis Willard <travisw at wmpub.ca>
+# Contributor: Georg Grabler <ggrabler at gmail.com>
+
+pkgname=ktorrent
+pkgver=20.11.80
+pkgrel=1
+pkgdesc="A powerful BitTorrent client for KDE"
+arch=(x86_64)
+url='https://www.kde.org/applications/internet/ktorrent/'
+license=(GPL2)
+depends=(libktorrent kcmutils knotifyconfig kross phonon-qt5 qt5-webengine)
+makedepends=(extra-cmake-modules kdoctools boost plasma-workspace kdnssd taglib syndication kplotting geoip)
+optdepends=('plasma-workspace: shutdown plugin' 'kdnssd: zeroconf plugin' 'taglib: mediaplayer plugin' 'geoip: info widget plugin'
+            'syndication: syndication plugin' 'kplotting: statistics plugin')
+groups=(kde-applications kde-network)
+source=("https://download.kde.org/unstable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('8b4fa4214e4d78db689b37c73cdcd1ddb7e463dfb3050526719b4111289205be'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DWITH_SYSTEM_GEOIP=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}