[arch-commits] Commit in kdelibs4support/repos (2 files)

[Antonio Rojas]

    Date: Saturday, November 14, 2020 @ 10:46:20
  Author: arojas
Revision: 401093

archrelease: copy trunk to testing-x86_64

Added:
  kdelibs4support/repos/testing-x86_64/
  kdelibs4support/repos/testing-x86_64/PKGBUILD
    (from rev 401092, kdelibs4support/trunk/PKGBUILD)

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Copied: kdelibs4support/repos/testing-x86_64/PKGBUILD (from rev 401092, kdelibs4support/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-11-14 10:46:20 UTC (rev 401093)
@@ -0,0 +1,34 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kdelibs4support
+pkgver=5.76.0
+pkgrel=1
+pkgdesc='Porting aid from KDELibs4'
+arch=(x86_64)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(kunitconversion kitemmodels kemoticons kparts perl)
+makedepends=(extra-cmake-modules kdoctools qt5-tools networkmanager perl-uri kdesignerplugin)
+groups=(kf5-aids)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/portingAids/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('b581273dfaebc5697eb7aa616d858119227dd6c5b781f216abdbff1d93076f0d'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+# cert bundle seems to be hardcoded
+# link it to the one from ca-certificates
+  rm -f "$pkgdir"/usr/share/kf5/kssl/ca-bundle.crt
+  ln -sf /etc/ssl/certs/ca-certificates.crt "$pkgdir"/usr/share/kf5/kssl/ca-bundle.crt
+}