[arch-commits] Commit in haskell-hedgehog/repos (2 files)

[Felix Yan]

    Date: Monday, November 16, 2020 @ 02:44:48
  Author: felixonmars
Revision: 755117

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hedgehog/repos/community-staging-x86_64/
  haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD
    (from rev 755116, haskell-hedgehog/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD (from rev 755116, haskell-hedgehog/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-16 02:44:48 UTC (rev 755117)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hedgehog
+pkgname=haskell-hedgehog
+pkgver=1.0.3
+pkgrel=50
+pkgdesc="A modern property-based testing system"
+url="https://hedgehog.qa"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-concurrent-output'
+         'haskell-erf' 'haskell-lifted-async' 'haskell-mmorph'
+         'haskell-monad-control' 'haskell-pretty-show' 'haskell-primitive' 'haskell-random'
+         'haskell-resourcet' 'haskell-transformers-base' 'haskell-wl-pprint-annotated')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c04955a1189c85ec8c66ecdd97ea4bdd8a4587a7f999c38bd5e5ab4d51469a075f4f33c73f5a75fd74572c9c87ec32fea21e67fc66f61b7d3f5d30286f5b5536')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/semigroups/d;/fail/d;s/< *1.2/<2/;s/< *0.11/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}