[arch-commits] Commit in haskell-deferred-folds/repos (2 files)

[Felix Yan]

    Date: Monday, November 16, 2020 @ 17:18:08
  Author: felixonmars
Revision: 755416

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-deferred-folds/repos/community-staging-x86_64/
  haskell-deferred-folds/repos/community-staging-x86_64/PKGBUILD
    (from rev 755415, haskell-deferred-folds/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-deferred-folds/repos/community-staging-x86_64/PKGBUILD (from rev 755415, haskell-deferred-folds/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-16 17:18:08 UTC (rev 755416)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=deferred-folds
+pkgname=haskell-deferred-folds
+pkgver=0.9.11
+pkgrel=19
+pkgdesc="Abstractions over deferred folds"
+url="https://github.com/metrix-ai/deferred-folds"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-foldl' 'haskell-hashable' 'haskell-primitive'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-rerebase'
+             'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('2e4a6ebd58e43e33870d757d3c512c59c8eaf030867e9980d5263db95d13008777e03c0a36f954b5756b62ee152ea0a3958f29ca09b111e3ce1f59b071ffea82')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}