[arch-commits] Commit in clevis/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Jonas Witschel]

    Date: Monday, November 16, 2020 @ 19:06:03
  Author: diabonas
Revision: 755528

archrelease: copy trunk to community-x86_64

Added:
  clevis/repos/community-x86_64/PKGBUILD
    (from rev 755527, clevis/trunk/PKGBUILD)
Deleted:
  clevis/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  104 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 55 insertions(+), 49 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-11-16 19:05:58 UTC (rev 755527)
+++ PKGBUILD	2020-11-16 19:06:03 UTC (rev 755528)
@@ -1,49 +0,0 @@
-# Maintainer: Jonas Witschel <diabonas at archlinux.org>
-pkgname=clevis
-pkgver=15
-_commit=6add2e9acbed9b4bcb50dcc60d4c72733bd65d14 # signed commit corresponding to tag "v$pkgver"
-pkgrel=1
-pkgdesc='Automated Encryption Framework'
-arch=('x86_64')
-url='https://github.com/latchset/clevis'
-license=('GPL3')
-depends=('bash' 'jose')
-makedepends=('git' 'meson' 'asciidoc' 'audit' 'bash-completion' 'cryptsetup' 'dracut' 'glib2'
-             'jansson' 'libpwquality' 'luksmeta' 'openssl' 'tpm2-tools' 'udisks2')
-checkdepends=('jq' 'tang')
-optdepends=('audit: UDisks2 unlocker support'
-            'cryptsetup: LUKS unlocker support'
-            'curl: Tang pin support'
-            'dracut: dracut unlocker support'
-            'glib2: UDisks2 unlocker support'
-            'jansson: SSS pin and UDisks2 unlocker support'
-            'libpwquality: LUKS unlocker support'
-            'luksmeta: LUKS and UDisks2 unlocker support'
-            'nmap: dracut unlocker support'
-            'openssl: SSS pin support'
-            'tpm2-tools: TPM2 pin support'
-            'udisks2: UDisks2 unlocker support')
-source=("git+$url.git?signed#commit=$_commit")
-sha512sums=('SKIP')
-validpgpkeys=('7CE2CB3D2AF59FE1EA22F551D0D219ED1F7E762C') # Sergio Correia <scorreia at redhat.com>
-
-pkgver() {
-	cd "$pkgname"
-	git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
-}
-
-build() {
-	cd "$pkgname"
-	meson --prefix=/usr --libexecdir=/usr/lib --buildtype=plain build
-	ninja -C build
-}
-
-check() {
-	cd "$pkgname"
-	ninja -C build test
-}
-
-package() {
-	cd "$pkgname"
-	DESTDIR="$pkgdir" ninja -C build install
-}

Copied: clevis/repos/community-x86_64/PKGBUILD (from rev 755527, clevis/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-11-16 19:06:03 UTC (rev 755528)
@@ -0,0 +1,55 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=clevis
+pkgver=15
+_commit=6add2e9acbed9b4bcb50dcc60d4c72733bd65d14 # git rev-parse "v$pkgver^{}"
+pkgrel=2
+pkgdesc='Automated Encryption Framework'
+arch=('x86_64')
+url='https://github.com/latchset/clevis'
+license=('GPL3')
+depends=('bash' 'jose')
+makedepends=('git' 'meson' 'asciidoc' 'audit' 'bash-completion' 'cryptsetup' 'dracut' 'glib2'
+             'jansson' 'libpwquality' 'luksmeta' 'openssl' 'tpm2-tools' 'udisks2')
+checkdepends=('jq' 'tang')
+optdepends=('audit: UDisks2 unlocker support'
+            'cryptsetup: LUKS unlocker support'
+            'curl: Tang pin support'
+            'dracut: dracut unlocker support'
+            'glib2: UDisks2 unlocker support'
+            'jansson: SSS pin and UDisks2 unlocker support'
+            'libpwquality: LUKS unlocker support'
+            'luksmeta: LUKS and UDisks2 unlocker support'
+            'nmap: dracut unlocker support'
+            'openssl: SSS pin support'
+            'tpm2-tools: TPM2 pin support'
+            'udisks2: UDisks2 unlocker support')
+source=("git+$url.git?signed#commit=$_commit")
+sha512sums=('SKIP')
+validpgpkeys=('7CE2CB3D2AF59FE1EA22F551D0D219ED1F7E762C') # Sergio Correia <scorreia at redhat.com>
+
+pkgver() {
+	cd "$pkgname"
+	git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "$pkgname"
+	# Add support for tpm2-tools 5.0
+	git cherry-pick --no-commit ef76951e4486dadf41ca8085e09849466a0c7fd3
+}
+
+build() {
+	cd "$pkgname"
+	meson --prefix=/usr --libexecdir=/usr/lib --buildtype=plain build
+	ninja -C build
+}
+
+check() {
+	cd "$pkgname"
+	ninja -C build test
+}
+
+package() {
+	cd "$pkgname"
+	DESTDIR="$pkgdir" ninja -C build install
+}