[arch-commits] Commit in lib32-util-linux/repos (2 files)

Christian Hesse eworm at archlinux.org
Tue Nov 17 08:52:40 UTC 2020


    Date: Tuesday, November 17, 2020 @ 08:52:40
  Author: eworm
Revision: 756072

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-util-linux/repos/multilib-testing-x86_64/
  lib32-util-linux/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 756071, lib32-util-linux/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: lib32-util-linux/repos/multilib-testing-x86_64/PKGBUILD (from rev 756071, lib32-util-linux/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2020-11-17 08:52:40 UTC (rev 756072)
@@ -0,0 +1,37 @@
+# Maintainer: Dave Reisner <dreisner at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+_pkgbasename=util-linux
+pkgname=lib32-$_pkgbasename
+_pkgmajor=2.36
+pkgver=${_pkgmajor}.1
+pkgrel=1
+pkgdesc="Miscellaneous system utilities for Linux (32-bit)"
+url='https://github.com/karelzak/util-linux'
+arch=('x86_64')
+depends=('lib32-glibc' "$_pkgbasename" 'lib32-libxcrypt')
+provides=('libuuid.so' 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so')
+license=('GPL2')
+options=('!emptydirs')
+validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284')  # Karel Zak
+source=("https://www.kernel.org/pub/linux/utils/util-linux/v$_pkgmajor/$_pkgbasename-$pkgver.tar."{xz,sign})
+sha256sums=('09fac242172cd8ec27f0739d8d192402c69417617091d8c6e974841568f37eed'
+            'SKIP')
+
+build() {
+  cd "$_pkgbasename-$pkgver"
+
+  ./configure \
+      CC="${CC:-cc} -m32" \
+      PKG_CONFIG_PATH="/usr/lib32/pkgconfig" \
+      --libdir=/usr/lib32
+
+  make lib{uuid,blkid,fdisk,mount,smartcols}.la
+}
+
+package() {
+  make -C "$_pkgbasename-$pkgver" \
+    DESTDIR="$pkgdir" \
+    install-usrlib_execLTLIBRARIES \
+    install-pkgconfigDATA
+}


More information about the arch-commits mailing list