[arch-commits] Commit in haskell-hspec-wai/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 17, 2020 @ 18:48:32
  Author: felixonmars
Revision: 756820

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-wai/repos/community-staging-x86_64/
  haskell-hspec-wai/repos/community-staging-x86_64/PKGBUILD
    (from rev 756819, haskell-hspec-wai/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-hspec-wai/repos/community-staging-x86_64/PKGBUILD (from rev 756819, haskell-hspec-wai/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-17 18:48:32 UTC (rev 756820)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hspec-wai
+pkgname=haskell-hspec-wai
+pkgver=0.11.0
+pkgrel=24
+pkgdesc="Experimental Hspec support for testing WAI applications"
+url="https://github.com/hspec/hspec-wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-base-compat' 'haskell-case-insensitive'
+         'haskell-hspec' 'haskell-hspec-core' 'haskell-hspec-expectations' 'haskell-http-types'
+         'haskell-wai' 'haskell-wai-extra')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('4b451744eae139787f9156cd6a59589e8c485ce1d98f49847344fb984eb3d7b6d265537feb4ad5ca57d439e2460b74cdd2ba16c7d657fd0c10575af354930ffc')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}