[arch-commits] Commit in haskell-warp/repos (2 files)

[Felix Yan]

    Date: Friday, November 20, 2020 @ 19:13:07
  Author: felixonmars
Revision: 758051

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-warp/repos/community-staging-x86_64/
  haskell-warp/repos/community-staging-x86_64/PKGBUILD
    (from rev 758049, haskell-warp/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-warp/repos/community-staging-x86_64/PKGBUILD (from rev 758049, haskell-warp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-20 19:13:07 UTC (rev 758051)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=warp
+pkgname=haskell-warp
+pkgver=3.3.13
+pkgrel=104
+pkgdesc="A fast, light-weight web server for WAI applications."
+url="https://github.com/yesodweb/wai"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-auto-update' 'haskell-bsb-http-chunked'
+         'haskell-case-insensitive' 'haskell-hashable' 'haskell-http-date' 'haskell-http-types'
+         'haskell-http2' 'haskell-iproute' 'haskell-network' 'haskell-simple-sendfile'
+         'haskell-streaming-commons' 'haskell-time-manager' 'haskell-unix-compat' 'haskell-vault'
+         'haskell-wai' 'haskell-word8' 'haskell-x509')
+makedepends=('ghc' 'haskell-doctest' 'haskell-http-client' 'haskell-hspec' 'haskell-hunit'
+             'haskell-lifted-base' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ac37e1f274d26b2c846429960074d27010c0864efd87da6d79f03e3f833aca3269176bb99301ab8cb59c4476ff12bae35b26e0fe602e7b0e2cad2837592e07b1')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-warp-debug -fallow-sendfilefd -f-network-bytestring
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}