[arch-commits] Commit in gnome-shell/repos (3 files)

[Jan Steffens]

    Date: Saturday, November 21, 2020 @ 19:36:34
  Author: heftig
Revision: 401642

archrelease: copy trunk to testing-x86_64

Added:
  gnome-shell/repos/testing-x86_64/
  gnome-shell/repos/testing-x86_64/PKGBUILD
    (from rev 401635, gnome-shell/trunk/PKGBUILD)
  gnome-shell/repos/testing-x86_64/gnome-shell.install
    (from rev 401635, gnome-shell/trunk/gnome-shell.install)

---------------------+
 PKGBUILD            |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 gnome-shell.install |    7 +++++++
 2 files changed, 57 insertions(+)

Copied: gnome-shell/repos/testing-x86_64/PKGBUILD (from rev 401635, gnome-shell/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-11-21 19:36:34 UTC (rev 401642)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=3.38.1+19+ge93b8263b
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL2)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session
+         gnome-settings-daemon gnome-themes-extra gsettings-desktop-schemas
+         libcanberra-pulse libgdm libsecret mutter nm-connection-editor unzip
+         gstreamer libibus gnome-autoar gnome-disk-utility gst-plugin-pipewire)
+makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
+             sassc asciidoc bash-completion)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+install=gnome-shell.install
+_commit=e93b8263b03ed8bbb3829ad82ebf3664197740c9  # gnome-3-38
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+  
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
+}
+
+package() {
+  depends+=(libmutter-7.so)
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: gnome-shell/repos/testing-x86_64/gnome-shell.install (from rev 401635, gnome-shell/trunk/gnome-shell.install)
===================================================================
--- testing-x86_64/gnome-shell.install	                        (rev 0)
+++ testing-x86_64/gnome-shell.install	2020-11-21 19:36:34 UTC (rev 401642)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/gnome-shell
+}
+
+post_upgrade() {
+  post_install
+}