[arch-commits] Commit in mutter/repos (3 files)

Jan Steffens heftig at archlinux.org
Sat Nov 21 19:36:34 UTC 2020


    Date: Saturday, November 21, 2020 @ 19:36:34
  Author: heftig
Revision: 401641

archrelease: copy trunk to testing-x86_64

Added:
  mutter/repos/testing-x86_64/
  mutter/repos/testing-x86_64/PKGBUILD
    (from rev 401635, mutter/trunk/PKGBUILD)
  mutter/repos/testing-x86_64/mutter.install
    (from rev 401635, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   58 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 ++++++
 2 files changed, 65 insertions(+)

Copied: mutter/repos/testing-x86_64/PKGBUILD (from rev 401635, mutter/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-11-21 19:36:34 UTC (rev 401641)
@@ -0,0 +1,58 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=3.38.1+44+gbd42c9c23b
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
+         libcanberra startup-notification zenity libsm gnome-desktop upower
+         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
+         xorg-server-xwayland graphene)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server sysprof)
+checkdepends=(xorg-server-xvfb)
+provides=(libmutter-7.so)
+groups=(gnome)
+install=mutter.install
+_commit=bd42c9c23b6f33bc3827b0ddb149ce2dcfb914ef  # gnome-3-38
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D xwayland_initfd=disabled \
+    -D installed_tests=false
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  # Stacking test flaky
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    meson test -C build --print-errorlogs || :
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/testing-x86_64/mutter.install (from rev 401635, mutter/trunk/mutter.install)
===================================================================
--- testing-x86_64/mutter.install	                        (rev 0)
+++ testing-x86_64/mutter.install	2020-11-21 19:36:34 UTC (rev 401641)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}


More information about the arch-commits mailing list