[arch-commits] Commit in haskell-gtk3/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Nov 22 21:42:53 UTC 2020


    Date: Sunday, November 22, 2020 @ 21:42:52
  Author: felixonmars
Revision: 759601

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-gtk3/repos/community-staging-x86_64/
  haskell-gtk3/repos/community-staging-x86_64/PKGBUILD
    (from rev 759600, haskell-gtk3/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: haskell-gtk3/repos/community-staging-x86_64/PKGBUILD (from rev 759600, haskell-gtk3/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-22 21:42:52 UTC (rev 759601)
@@ -0,0 +1,37 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=haskell-gtk3
+pkgver=0.15.5
+pkgrel=13
+pkgdesc="Binding to the gtk library for Gtk2Hs."
+url="https://hackage.haskell.org/package/gtk3"
+license=('LGPL2.1')
+arch=('x86_64')
+depends=('ghc-libs' 'gtk3' 'haskell-pango')
+makedepends=('ghc' 'haskell-gtk2hs-buildtools')
+provides=('gtk2hs-gtk' 'haskell-gtk')
+replaces=('gtk2hs-gtk' 'haskell-gtk')
+conflicts=('gtk2hs-gtk' 'haskell-gtk')
+source=("https://hackage.haskell.org/packages/archive/gtk3/${pkgver}/gtk3-${pkgver}.tar.gz")
+sha512sums=('937b250f04e797b821d560a768f9eaee448f2d2d98571b6ef401de44177f50861f557e653afc7f055dfa2e15180dca9d82e36469f0fb97dff5a170ebc6c62519')
+
+build() {
+    cd "${srcdir}/gtk3-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/gtk3-${pkgver}"
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+}



More information about the arch-commits mailing list