[arch-commits] Commit in haskell-swagger2/repos (2 files)

[Felix Yan]

    Date: Monday, November 23, 2020 @ 17:05:56
  Author: felixonmars
Revision: 760006

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-swagger2/repos/community-staging-x86_64/
  haskell-swagger2/repos/community-staging-x86_64/PKGBUILD
    (from rev 760005, haskell-swagger2/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-swagger2/repos/community-staging-x86_64/PKGBUILD (from rev 760005, haskell-swagger2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-23 17:05:56 UTC (rev 760006)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=swagger2
+pkgname=haskell-swagger2
+pkgver=2.6
+pkgrel=66
+pkgdesc="Swagger 2.0 data model"
+url="https://github.com/GetShopTV/swagger2"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-base-compat-batteries'
+         'haskell-cookie' 'haskell-hashable' 'haskell-generics-sop' 'haskell-http-media'
+         'haskell-insert-ordered-containers' 'haskell-lens' 'haskell-network' 'haskell-optics-core'
+         'haskell-optics-th' 'haskell-quickcheck' 'haskell-scientific'
+         'haskell-transformers-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-uuid-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-quickcheck-instances'
+             'haskell-hspec-discover' 'haskell-doctest' 'haskell-cabal-doctest' 'haskell-glob'
+             'haskell-utf8-string')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('d7ca7710ad1c1b42c7f9066b94a3abaf22be6826a84255dbbcbb0c0bbae3612cd934432fa907b4f650049e83fae94d6ead602e93f29e739f14c17144fe5a2101')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *2.14/<3/;s/< *1.5/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}