[arch-commits] Commit in php-snuffleupagus/repos (2 files)

Kpcyrd kpcyrd at archlinux.org
Tue Nov 24 17:35:43 UTC 2020


    Date: Tuesday, November 24, 2020 @ 17:35:42
  Author: kpcyrd
Revision: 760991

archrelease: copy trunk to community-x86_64

Added:
  php-snuffleupagus/repos/community-x86_64/
  php-snuffleupagus/repos/community-x86_64/PKGBUILD
    (from rev 760990, php-snuffleupagus/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: php-snuffleupagus/repos/community-x86_64/PKGBUILD (from rev 760990, php-snuffleupagus/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-11-24 17:35:42 UTC (rev 760991)
@@ -0,0 +1,37 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+# Contributor: Julien (jvoisin) Voisin <julien.voisin+snuffleupagus at dustri.org>
+
+pkgname=php-snuffleupagus
+_pkgname=snuffleupagus
+pkgver=0.6.0
+pkgrel=1
+pkgdesc="Security module for PHP"
+url='https://snuffleupagus.readthedocs.io/'
+arch=('x86_64')
+license=('LGPL3')
+depends=('php' 'pcre')
+backup=('etc/php/conf.d/snuffleupagus.ini'
+        'etc/php/conf.d/snuffleupagus.rules')
+source=(https://github.com/jvoisin/${_pkgname}/archive/v${pkgver}/${_pkgname}-${pkgver}.tar.gz)
+b2sums=('c37e247388c5ede3a2c065c5df42dba37e8da3f0fc2856a4d785c6e139fb13a6daf9a2feacde16c392a158f340f12b3b4724f23b05e4eb4f0e7c070c0fa907b2')
+
+build() {
+  cd ${_pkgname}-${pkgver}/src
+  phpize
+  ./configure --prefix=/usr --enable-"${_pkgname}"
+  make
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}/src
+  NO_INTERACTION=1 REPORT_EXIT_STATUS=1 make test
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  make -C src INSTALL_ROOT="${pkgdir}" install
+  install -D -m644 "config/default.rules" "${pkgdir}/etc/php/conf.d/${_pkgname}.rules"
+  install -D -m644 "config/${_pkgname}.ini" "${pkgdir}/etc/php/conf.d/${_pkgname}.ini"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list