[arch-commits] Commit in io/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Alexander Rødseth]

    Date: Wednesday, November 25, 2020 @ 17:33:50
  Author: arodseth
Revision: 761132

archrelease: copy trunk to community-x86_64

Added:
  io/repos/community-x86_64/PKGBUILD
    (from rev 761131, io/trunk/PKGBUILD)
Deleted:
  io/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   82 ++++++++++++++++++++++++++++++++++++-------------------------
 1 file changed, 49 insertions(+), 33 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-11-25 17:33:44 UTC (rev 761131)
+++ PKGBUILD	2020-11-25 17:33:50 UTC (rev 761132)
@@ -1,33 +0,0 @@
-# Maintainer: Alexander F Rødseth <xyproto at archlinux.org>
-# Contributor: Gergely Imreh <imrehg at gmail.com>
-
-pkgname=io
-pkgver=2017.06.08
-pkgrel=7
-pkgdesc='IO programming language'
-arch=('x86_64')
-url='http://iolanguage.com/'
-license=('BSD')
-depends=('pcre' 'libsndfile' 'libxmu' 'freetype2' 'libedit' 'libxml2' 'libtiff' 'libevent' 'yajl' 'mariadb-libs' 'lzo' 'libpng' 'util-linux' 'freeglut' 'libjpeg-turbo' 'libtheora' 'python')
-makedepends=('cmake' 'git')
-options=('!makeflags' '!buildflags')
-source=("git+https://github.com/stevedekorte/io#commit=5fffec7cbe9679632ff793befacedd92f79d7f0f")
-sha256sums=('SKIP')
-
-prepare() {
-  sed -i "s:20151111:${pkgver//./}:" io/libs/iovm/source/IoVersion.h
-}
-
-build() {
-  mkdir -p build
-  cd build
-  cmake ../io -DCMAKE_INSTALL_PREFIX=/usr
-}
-
-package() {
-  DESTDIR="$pkgdir" make -C build install
-  install -Dm644 io/license/bsd_license.txt \
-    "$pkgdir/usr/share/licenses/$pkgname/bsd_license.txt"
-}
-
-# vim: ts=2 sw=2 et:

Copied: io/repos/community-x86_64/PKGBUILD (from rev 761131, io/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-11-25 17:33:50 UTC (rev 761132)
@@ -0,0 +1,49 @@
+# Maintainer: Alexander F Rødseth <xyproto at archlinux.org>
+# Contributor: loqs
+# Contributor: Mark E.A.
+# Contributor: Gergely Imreh <imrehg at gmail.com>
+
+pkgname=io
+pkgver=2017.09.06
+pkgrel=1
+pkgdesc='IO programming language'
+arch=(x86_64)
+url='https://iolanguage.com/'
+license=(BSD)
+depends=(freeglut freetype2 libedit libevent libjpeg-turbo libpng libsndfile libtheora libtiff libxml2 libxmu lzo mariadb-libs pcre python sqlite util-linux yajl)
+makedepends=(cmake git)
+options=(!makeflags)
+source=("git+https://github.com/stevedekorte/io#commit=b8a18fc199758ed09cd2f199a9bc821f6821072a" # tag: 2017.09.06
+        'noexec.patch::https://github.com/IoLanguage/io/commit/5b88e9769c1d4629e9a4a01c78b57c0d80c7a70c.patch')
+sha256sums=('SKIP'
+            '4f322ddbb6427d8b3ddc9d34786b9676b3cec26c867040626b6246d03e9dad24')
+
+prepare() {
+  cd $pkgname
+  sed -i 's,sys/sysctl.h,linux/sysctl.h,g' libs/iovm/source/IoSystem.c
+  sed -ri "s,20[0-9]+,$pkgver," libs/iovm/source/IoVersion.h
+  git submodule update --init
+}
+
+build() {
+   cmake \
+    -B build \
+    -S $pkgname \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D CMAKE_SKIP_RPATH=1
+  make -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" make -C build install
+
+  # The dynamically linked io executable does not work, see FS#68674. The error is:
+  # Relink `/usr/lib/libbasekit.so' with `/usr/lib/libm.so.6' for IFUNC symbol `ceil'
+  # Use the statically linked executable instead.
+  mv -f "$pkgdir/usr/bin/io_static" "$pkgdir/usr/bin/io"
+
+  # In the next version of io, it's just $pkgname/LICENSE.txt
+  install -Dm644 $pkgname/license/bsd_license.txt \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}