[arch-commits] Commit in darcs/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 25, 2020 @ 20:57:44
  Author: felixonmars
Revision: 761290

archrelease: copy trunk to community-staging-x86_64

Added:
  darcs/repos/community-staging-x86_64/
  darcs/repos/community-staging-x86_64/PKGBUILD
    (from rev 761289, darcs/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: darcs/repos/community-staging-x86_64/PKGBUILD (from rev 761289, darcs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-25 20:57:44 UTC (rev 761290)
@@ -0,0 +1,67 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=darcs
+pkgver=2.16.3
+pkgrel=18
+pkgdesc="A distributed, interactive, smart revision control system"
+url="http://darcs.net"
+license=("GPL")
+arch=('x86_64')
+depends=('curl' 'ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-conduit' 'haskell-constraints' 'haskell-cryptonite' 'haskell-data-ordlist'
+         'haskell-fgl' 'haskell-hashable' 'haskell-html' 'haskell-http-conduit' 'haskell-http-types'
+         'haskell-knob' 'haskell-memory' 'haskell-mmap' 'haskell-network' 'haskell-network-uri'
+         'haskell-old-time' 'haskell-regex-applicative' 'haskell-regex-compat-tdfa'
+         'haskell-tar' 'haskell-temporary' 'haskell-unix-compat' 'haskell-utf8-string'
+         'haskell-vector' 'haskell-zip-archive' 'haskell-zlib')
+makedepends=('ghc' 'uusi' 'haskell-cmdargs' 'haskell-findbin' 'haskell-hunit' 'haskell-leancheck'
+             'haskell-quickcheck' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-leancheck' 'haskell-test-framework-quickcheck2'
+             # Added for their bundled shelly
+             'haskell-exceptions' 'haskell-monad-control' 'haskell-system-filepath'
+             'haskell-system-fileio' 'haskell-transformers-base')
+checkdepends=('bc' 'time')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('267787c5b3111a20158858b42a8b9c2698b80dc40f7d340175e26d74b955643cefffc2f4de9811fa26464eac2e79913150fb3cd73871275725d10a690b9d73c3')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -e 's/^ghc /ghc -dynamic /' \
+        -e 's/ ghc / ghc -dynamic /' \
+        -i tests/*.sh tests/lib
+    uusi $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+        -fcurl -fpkgconfig -f-static -fterminfo -fthreaded -fexecutable \
+        -f-rts -foptimize -f-warn-as-error -f-libiconv
+    LD_LIBRARY_PATH="$srcdir"/$pkgname-$pkgver/dist/build runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+    chmod 644 "${pkgdir}/usr/share/man/man1/darcs.1"
+
+    install -Dm644 contrib/darcs_completion "${pkgdir}/usr/share/bash-completion/completions/darcs"
+    install -Dm644 contrib/_darcs.zsh "${pkgdir}/usr/share/zsh/site-functions/_darcs"
+}