[arch-commits] Commit in (3 files)

Antonio Rojas arojas at archlinux.org
Fri Nov 27 21:34:22 UTC 2020


    Date: Friday, November 27, 2020 @ 21:34:22
  Author: arojas
Revision: 764729

Add plasma5-applet-window-buttons and split libappletdecoration to use it in mauikit

Added:
  plasma5-applets-window-buttons/
  plasma5-applets-window-buttons/trunk/
  plasma5-applets-window-buttons/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: plasma5-applets-window-buttons/trunk/PKGBUILD
===================================================================
--- plasma5-applets-window-buttons/trunk/PKGBUILD	                        (rev 0)
+++ plasma5-applets-window-buttons/trunk/PKGBUILD	2020-11-27 21:34:22 UTC (rev 764729)
@@ -0,0 +1,31 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgbase=plasma5-applets-window-buttons
+pkgname=(libappletdecoration plasma5-applets-window-buttons)
+pkgver=0.8.1
+pkgrel=2
+pkgdesc="Plasma 5 applet in order to show window buttons in your panels"
+arch=(x86_64)
+url="https://github.com/psifidotos/applet-window-buttons"
+license=(GPL)
+makedepends=(extra-cmake-modules kdecoration plasma-framework)
+source=($pkgname-$pkgver.tar.gz::"https://github.com/psifidotos/applet-window-buttons/archive/$pkgver.tar.gz")
+sha256sums=('9f7afca910072d3e6b23e9aad1bd0905965b2022e0498b43173d7a712cca8986')
+
+build() {
+  cmake -B build -S applet-window-buttons-$pkgver
+  cmake --build build
+}
+
+package_libappletdecoration() {
+  pkgdesc="Library for applet window decorations"
+  depends=(kdecoration plasma-framework)
+  DESTDIR="$pkgdir" cmake --install build/libappletdecoration
+}
+
+package_plasma5-applets-window-buttons() {
+  depends=(libappletdecoration plasma-workspace)
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/lib # Provided by libappletdecoration
+}
+


More information about the arch-commits mailing list