[arch-commits] Commit in (mutter6 mutter6/trunk mutter6/trunk/PKGBUILD)

[Maxime Gauduin]

    Date: Friday, October 2, 2020 @ 07:08:49
  Author: alucryd
Revision: 397071

add a compat mutter6 package

Added:
  mutter6/
  mutter6/trunk/
  mutter6/trunk/PKGBUILD

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Added: mutter6/trunk/PKGBUILD
===================================================================
--- mutter6/trunk/PKGBUILD	                        (rev 0)
+++ mutter6/trunk/PKGBUILD	2020-10-02 07:08:49 UTC (rev 397071)
@@ -0,0 +1,67 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter6
+pkgver=3.36.6
+pkgrel=1
+pkgdesc='A window manager for GNOME'
+url=https://gitlab.gnome.org/GNOME/mutter
+arch=(x86_64)
+license=(GPL2)
+depends=(
+  dconf
+  gnome-desktop
+  gnome-settings-daemon
+  gobject-introspection-runtime
+  gsettings-desktop-schemas
+  libcanberra
+  libgudev
+  libinput
+  libsm
+  libxkbcommon-x11
+  pipewire
+  startup-notification
+  upower
+  xorg-server-xwayland
+  zenity
+)
+makedepends=(
+  egl-wayland
+  git
+  gobject-introspection
+  meson
+  xorg-server
+)
+checkdepends=(xorg-server-xvfb)
+provides=(libmutter-6.so)
+_tag=7d1e9e77a914d71b902ba2dd8c2f51a16000b908
+source=(git+https://gitlab.gnome.org/GNOME/mutter.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd mutter
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson mutter build \
+    --libexecdir /usr/lib/mutter-6 \
+    -D egl_device=true \
+    -D installed_tests=false \
+    -D profiler=false \
+    -D wayland_eglstream=true \
+    -D xwayland_initfd=disabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  rm -rf "${pkgdir}"/usr/{bin,share}
+}
+
+# vim: ts=2 sw=2 et: