[arch-commits] Commit in gnome-latex/repos (2 files)

[Jan Steffens]

    Date: Friday, October 2, 2020 @ 21:11:58
  Author: heftig
Revision: 715705

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-latex/repos/community-staging-x86_64/
  gnome-latex/repos/community-staging-x86_64/PKGBUILD
    (from rev 715704, gnome-latex/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: gnome-latex/repos/community-staging-x86_64/PKGBUILD (from rev 715704, gnome-latex/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-02 21:11:58 UTC (rev 715705)
@@ -0,0 +1,44 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Tobias Bohrmann (PlainTextField) <honeypot.carbage at aechelon.de>
+# Contributor: Bernd Prünster (JesusMcCloud) <aur at berndpruenster.org>
+
+pkgname=gnome-latex
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="LaTeX editor for the GNOME desktop"
+arch=(x86_64)
+url="https://wiki.gnome.org/Apps/GNOME-LaTeX"
+license=(GPL3)
+depends=(gsettings-desktop-schemas gspell libgee tepl)
+makedepends=(gobject-introspection intltool itstool vala git gtk-doc yelp-tools
+             autoconf-archive appstream-glib)
+optdepends=('texlive-core: build LaTeX documents')
+replaces=(latexila)
+_commit=15076c006070cbc495f5b2afb095c0ec092291aa  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-latex.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --enable-gtk-doc
+  make
+}
+
+check() {
+  make -C $pkgname check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}