[arch-commits] Commit in gnome-boxes/repos (2 files)

[Jan Steffens]

    Date: Friday, October 2, 2020 @ 21:12:21
  Author: heftig
Revision: 715708

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-boxes/repos/community-staging-x86_64/
  gnome-boxes/repos/community-staging-x86_64/PKGBUILD
    (from rev 715707, gnome-boxes/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: gnome-boxes/repos/community-staging-x86_64/PKGBUILD (from rev 715707, gnome-boxes/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-02 21:12:21 UTC (rev 715708)
@@ -0,0 +1,48 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Stefano Facchini <stefano.facchini at gmail.com>
+
+pkgname=gnome-boxes
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="Simple GNOME application to access remote or virtual systems"
+arch=(x86_64)
+url="https://wiki.gnome.org/Apps/Boxes"
+license=(LGPL)
+groups=(gnome)
+depends=(cdrtools gtk-vnc libarchive libgudev libosinfo libsecret libvirt-glib
+         mtools qemu spice-gtk tracker webkit2gtk freerdp gtksourceview4
+         libhandy0)
+makedepends=(git gobject-introspection yelp-tools meson spice-protocol vala)
+_commit=fad33e0ca3109b69b340e71f4453534ccbb0337c  # tags/v3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-boxes.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/gtk-frdp.git"
+        "git+https://gitlab.gnome.org/felipeborges/libovf-glib.git")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git submodule init
+  git submodule set-url subprojects/gtk-frdp "$srcdir/gtk-frdp"
+  git submodule set-url subprojects/libovf-glib "$srcdir/libovf-glib"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}