[arch-commits] Commit in gnome-tweaks/repos (testing-any testing-any/PKGBUILD)

[Jan Steffens]

    Date: Monday, October 5, 2020 @ 13:36:44
  Author: heftig
Revision: 397293

archrelease: copy trunk to testing-any

Added:
  gnome-tweaks/repos/testing-any/
  gnome-tweaks/repos/testing-any/PKGBUILD
    (from rev 397292, gnome-tweaks/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: gnome-tweaks/repos/testing-any/PKGBUILD (from rev 397292, gnome-tweaks/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2020-10-05 13:36:44 UTC (rev 397293)
@@ -0,0 +1,37 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gnome-tweaks
+pkgver=3.34.0
+pkgrel=4
+pkgdesc="Graphical interface for advanced GNOME 3 settings (Tweak Tool)"
+url="https://wiki.gnome.org/Apps/Tweaks"
+arch=(any)
+license=(GPL)
+depends=(gnome-settings-daemon python-gobject libhandy0)
+makedepends=(git meson)
+groups=(gnome-extra)
+provides=("gnome-tweak-tool=$pkgver")
+conflicts=(gnome-tweak-tool)
+replaces=(gnome-tweak-tool)
+_commit=44f73bb706863aae50a52bb9514c525cdc01293d  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-tweaks.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}