[arch-commits] Commit in (libb2 libb2/trunk libb2/trunk/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Tue Oct 6 16:21:32 UTC 2020


    Date: Tuesday, October 6, 2020 @ 16:21:31
  Author: arojas
Revision: 397396

New Qt 6 dependency

Added:
  libb2/
  libb2/trunk/
  libb2/trunk/PKGBUILD

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Added: libb2/trunk/PKGBUILD
===================================================================
--- libb2/trunk/PKGBUILD	                        (rev 0)
+++ libb2/trunk/PKGBUILD	2020-10-06 16:21:31 UTC (rev 397396)
@@ -0,0 +1,35 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Lex Black <autumn-wind at web.de>
+# Contributor: Jesin <Jesin00 at gmail.com>
+
+pkgname=libb2
+pkgver=0.98.1
+pkgrel=2
+arch=(x86_64)
+pkgdesc='C library providing BLAKE2b, BLAKE2s, BLAKE2bp, BLAKE2sp hash functions'
+url='https://blake2.net/'
+license=(custom:CC0)
+depends=(gcc-libs)
+source=("https://github.com/BLAKE2/libb2/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('53626fddce753c454a3fea581cbbc7fe9bbcf0bc70416d48fdbbf5d87ef6c72e')
+
+# libb2's build system discards the $CFLAGS variable.
+# We can get around this by putting those flags in $CC.
+export CC="${CC-cc} $CFLAGS"
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure --prefix=/usr --disable-static --enable-shared --disable-native --enable-fat
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
+}


More information about the arch-commits mailing list