[arch-commits] Commit in (3 files)
Antonio Rojas
arojas at archlinux.org
Tue Oct 6 17:04:05 UTC 2020
Date: Tuesday, October 6, 2020 @ 17:04:05
Author: arojas
Revision: 397398
Initial Qt6 packages
Added:
qt6-base/
qt6-base/kde-unstable/
qt6-base/kde-unstable/PKGBUILD
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Added: qt6-base/kde-unstable/PKGBUILD
===================================================================
--- qt6-base/kde-unstable/PKGBUILD (rev 0)
+++ qt6-base/kde-unstable/PKGBUILD 2020-10-06 17:04:05 UTC (rev 397398)
@@ -0,0 +1,55 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=qt6-base
+_qtver=6.0.0-alpha
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='A cross-platform application and UI framework'
+depends=(libjpeg-turbo xcb-util-keysyms xcb-util-cursor libgl fontconfig xdg-utils
+ shared-mime-info xcb-util-wm libxrender libxi sqlite mesa
+ tslib libinput libxkbcommon-x11 libproxy libcups double-conversion md4c brotli libb2)
+makedepends=(cmake libfbclient mariadb-libs unixodbc postgresql alsa-lib gst-plugins-base-libs
+ gtk3 libpulse cups freetds vulkan-headers)
+optdepends=('postgresql-libs: PostgreSQL driver'
+ 'mariadb-libs: MariaDB driver'
+ 'unixodbc: ODBC driver'
+ 'libfbclient: Firebird/iBase driver'
+ 'freetds: MS SQL driver'
+ 'gtk3: GTK platform plugin'
+ 'perl: for syncqt')
+groups=(qt6)
+_pkgfn="${pkgname/6-/}-everywhere-src-${_qtver}"
+source=("https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz")
+sha256sums=('1816c4490d3f1f6c6ae3f57a3ec9dff4e8bcab2951786cb0f457847c7ab0e8fa')
+
+build() {
+ cmake -B build -S $_pkgfn \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DINSTALL_BINDIR=lib/qt6/bin \
+ -DINSTALL_DOCDIR=share/doc/qt6 \
+ -DINSTALL_ARCHDATADIR=lib/qt6 \
+ -DINSTALL_DATADIR=share/qt6 \
+ -DINSTALL_INCLUDEDIR=include/qt6 \
+ -DINSTALL_MKSPECSDIR=lib/qt6/mkspecs \
+ -DINSTALL_EXAMPLESDIR=share/doc/qt6/examples \
+ -DQT_FEATURE_journald=ON \
+ -DQT_FEATURE_openssl_linked=ON
+ cmake --build build
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+
+ install -Dm644 $_pkgfn/LICENSE* -t "$pkgdir"/usr/share/licenses/$pkgbase
+
+ # Symlinks for backwards compatibility
+ mkdir -p "$pkgdir"/usr/bin
+ for _b in uic rcc qmake; do
+ ln -rs "$pkgdir"/usr/lib/qt6/bin/$_b "$pkgdir"/usr/bin/$_b-qt6
+ done
+}
More information about the arch-commits
mailing list