[arch-commits] Commit in haskell-x11/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Oct 7 14:39:37 UTC 2020


    Date: Wednesday, October 7, 2020 @ 14:39:36
  Author: felixonmars
Revision: 720671

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-x11/repos/community-staging-x86_64/
  haskell-x11/repos/community-staging-x86_64/PKGBUILD
    (from rev 720670, haskell-x11/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-x11/repos/community-staging-x86_64/PKGBUILD (from rev 720670, haskell-x11/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-07 14:39:36 UTC (rev 720671)
@@ -0,0 +1,40 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: shild <sxp at bk.ru>
+# Maintainer: Vesa Kaihlavirta <vegai at iki.fi>
+
+_hkgname=X11
+pkgname=haskell-x11
+pkgver=1.9.2
+pkgrel=11
+pkgdesc="A Haskell binding to the X11 graphics library."
+arch=(x86_64)
+url="https://hackage.haskell.org/cgi-bin/hackage-scripts/package/X11"
+license=('BSD')
+depends=('ghc-libs' "libx11" "libxinerama" "libxrandr" "libxss" "haskell-data-default")
+conflicts=(haskell-x11-extras)
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/X11/$pkgver/X11-$pkgver.tar.gz)
+sha512sums=('e9658c33b6dcbb6a42f1cc4a8976365506af94ddc15c32f73205b453934ef3232f3b383f8365b6aa6e69b51acfda4a0f3a8038f3164523b33781139a80582a41')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list