[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Wed Oct 7 22:39:00 UTC 2020


    Date: Wednesday, October 7, 2020 @ 22:39:00
  Author: felixonmars
Revision: 721635

addpkg: haskell-ghc-exactprint 0.6.3.2-1

Added:
  haskell-ghc-exactprint/
  haskell-ghc-exactprint/repos/
  haskell-ghc-exactprint/trunk/
  haskell-ghc-exactprint/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-ghc-exactprint/trunk/PKGBUILD
===================================================================
--- haskell-ghc-exactprint/trunk/PKGBUILD	                        (rev 0)
+++ haskell-ghc-exactprint/trunk/PKGBUILD	2020-10-07 22:39:00 UTC (rev 721635)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-exactprint
+pkgname=haskell-ghc-exactprint
+pkgver=0.6.3.2
+pkgrel=1
+pkgdesc="ExactPrint for GHC"
+url="https://github.com/alanz/ghc-exactprint.git"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-free' 'haskell-ghc-paths' 'haskell-syb')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-filemanip' 'haskell-silently')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('96d68d45f1bef87efc586c4105d6723c4b38785a031181d9b11788ef5445eeaf')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list