[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Wed Oct 7 23:11:17 UTC 2020


    Date: Wednesday, October 7, 2020 @ 23:11:16
  Author: felixonmars
Revision: 721639

addpkg: haskell-retrie 0.1.1.1-1

Added:
  haskell-retrie/
  haskell-retrie/repos/
  haskell-retrie/trunk/
  haskell-retrie/trunk/PKGBUILD

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Added: haskell-retrie/trunk/PKGBUILD
===================================================================
--- haskell-retrie/trunk/PKGBUILD	                        (rev 0)
+++ haskell-retrie/trunk/PKGBUILD	2020-10-07 23:11:16 UTC (rev 721639)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=retrie
+pkgname=haskell-retrie
+pkgver=0.1.1.1
+pkgrel=1
+pkgdesc="A powerful, easy-to-use codemodding tool for Haskell."
+url="https://github.com/facebookincubator/retrie"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-data-default'
+         'haskell-ghc-exactprint' 'haskell-src-exts' 'haskell-optparse-applicative'
+         'haskell-random-shuffle' 'haskell-syb' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-ghc-paths' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-temporary')
+checkdepends=('git' 'mercurial')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('f162028ecbfea991f8a22701637b3869c8bd306f48823316c92496e4ea66d7d0')
+
+prepare() {
+  uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+  rm "$pkgdir"/usr/bin/demo
+}


More information about the arch-commits mailing list