[arch-commits] Commit in python-anyio/repos (community-any community-any/PKGBUILD)

Chih-Hsuan Yen yan12125 at archlinux.org
Fri Oct 9 04:50:22 UTC 2020


    Date: Friday, October 9, 2020 @ 04:50:21
  Author: yan12125
Revision: 722268

archrelease: copy trunk to community-any

Added:
  python-anyio/repos/community-any/
  python-anyio/repos/community-any/PKGBUILD
    (from rev 722267, python-anyio/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-anyio/repos/community-any/PKGBUILD (from rev 722267, python-anyio/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2020-10-09 04:50:21 UTC (rev 722268)
@@ -0,0 +1,39 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-anyio
+pkgver=2.0.2
+pkgrel=1
+pkgdesc='High level compatibility layer for multiple asynchronous event loop implementations'
+arch=(any)
+url='https://github.com/agronholm/anyio'
+license=(MIT)
+depends=(python python-idna python-sniffio)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest python-trustme python-hypothesis python-uvloop
+              python-curio python-trio)
+optdepends=(
+  'python-curio: curio backend'
+  'python-trio: trio backend'
+)
+source=(https://github.com/agronholm/anyio/archive/$pkgver/anyio-$pkgver.tar.gz)
+sha256sums=('2439f9d71d793d72d4e223632b9ef8beafc021989efac7b049f0c73280322d2a')
+
+build() {
+  cd anyio-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd anyio-$pkgver
+  # Install to a temporary root as the test suite requires the entry point for
+  # its pytest plugin
+  pyver=$(python -c "import sys; print('{}.{}'.format(*sys.version_info[:2]))")
+  python setup.py install --root="$PWD/tmp_install" --skip-build
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python$pyver/site-packages" pytest
+}
+
+package() {
+  cd anyio-$pkgver
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}


More information about the arch-commits mailing list