[arch-commits] Commit in haskell-jose/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Oct 9 22:50:42 UTC 2020


    Date: Friday, October 9, 2020 @ 22:50:42
  Author: felixonmars
Revision: 722831

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-jose/repos/community-staging-x86_64/
  haskell-jose/repos/community-staging-x86_64/PKGBUILD
    (from rev 722830, haskell-jose/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-jose/repos/community-staging-x86_64/PKGBUILD (from rev 722830, haskell-jose/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-09 22:50:42 UTC (rev 722831)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=jose
+pkgname=haskell-jose
+pkgver=0.8.4
+pkgrel=9
+pkgdesc="Javascript Object Signing and Encryption and JSON Web Token library"
+url="https://github.com/frasertweedale/hs-jose"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base64-bytestring' 'haskell-concise'
+         'haskell-cryptonite' 'haskell-lens' 'haskell-memory' 'haskell-monad-time'
+         'haskell-safe' 'haskell-aeson' 'haskell-unordered-containers' 'haskell-network-uri'
+         'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-x509' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('4141e8f48b97b0d801fab576c3098b95dc1cc9b7c98815cff6bd62324aa2c6d5a4648734d14a00ef08aa36c523befdc6cb7dfdadb9d92d0dce2b434ef8165882')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list