[arch-commits] Commit in tamarin-prover/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Oct 10 10:20:43 UTC 2020


    Date: Saturday, October 10, 2020 @ 10:20:42
  Author: felixonmars
Revision: 723071

archrelease: copy trunk to community-staging-x86_64

Added:
  tamarin-prover/repos/community-staging-x86_64/
  tamarin-prover/repos/community-staging-x86_64/PKGBUILD
    (from rev 723070, tamarin-prover/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: tamarin-prover/repos/community-staging-x86_64/PKGBUILD (from rev 723070, tamarin-prover/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-10 10:20:42 UTC (rev 723071)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=tamarin-prover
+pkgver=1.6.0
+pkgrel=24
+pkgdesc="The Tamarin prover for security protocol analysis"
+url="https://tamarin-prover.github.io"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'graphviz' 'maude' 'haskell-hunit' 'haskell-binary-orphans' 'haskell-binary-instances'
+         'haskell-blaze-builder' 'haskell-blaze-html' 'haskell-cmdargs' 'haskell-conduit'
+         'haskell-fclabels' 'haskell-file-embed' 'haskell-gitrev' 'haskell-http-types'
+         'haskell-lifted-base' 'haskell-monad-unlift' 'haskell-resourcet' 'haskell-safe'
+         'haskell-shakespeare' 'haskell-threads' 'haskell-wai' 'haskell-warp' 'haskell-yesod-core'
+         'haskell-yesod-static' 'haskell-tamarin-prover-utils' 'haskell-tamarin-prover-term'
+         'haskell-tamarin-prover-theory' 'haskell-tamarin-prover-sapic')
+optdepends=('ocaml: for sapic support')
+makedepends=('ghc' 'ocaml>=4.11.0')
+source=("tamarin-prover-$pkgver.tar.gz::https://github.com/tamarin-prover/tamarin-prover/archive/$pkgver.tar.gz")
+sha512sums=('7f3569f740d63d715b92a8f073eaecb8b32efe59b910b246977d36bb9e873765440e72feb6e76c7cbafab0495b88cfc666bb1dd12f685627c60d5cbd97b2973e')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i '/cp sapic/d' plugins/sapic/Makefile
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-executable-dynamic --prefix=/usr \
+        --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+            -fthreaded -ftest-coverage -f-build-tests --ghc-option='-pie'
+    runhaskell Setup build $MAKEFLAGS
+
+    cd plugins/sapic
+    make -j1
+}
+
+package() {
+    cd $pkgname-$pkgver
+    runhaskell Setup copy --destdir="${pkgdir}"
+
+    install -Dm644 etc/filetype.vim "$pkgdir"/usr/share/vim/vimfiles/ftdetect/tamarin.vim
+    install -Dm644 etc/syntax/spthy.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/spthy.vim
+    ln -s spthy.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/sapic.vim
+
+    cd plugins/sapic
+    install -Dm755 sapic "$pkgdir"/usr/bin/sapic
+}


More information about the arch-commits mailing list