[arch-commits] Commit in (bcc bcc/repos bcc/trunk bcc/trunk/PKGBUILD)
Anatol Pomozov
anatolik at archlinux.org
Mon Oct 12 01:53:49 UTC 2020
Date: Monday, October 12, 2020 @ 01:53:47
Author: anatolik
Revision: 723566
bcc: move package from AUR to [community]
Added:
bcc/
bcc/repos/
bcc/trunk/
bcc/trunk/PKGBUILD
----------+
PKGBUILD | 88 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 88 insertions(+)
Added: bcc/trunk/PKGBUILD
===================================================================
--- bcc/trunk/PKGBUILD (rev 0)
+++ bcc/trunk/PKGBUILD 2020-10-12 01:53:47 UTC (rev 723566)
@@ -0,0 +1,88 @@
+# Maintainer: Anatol Pomozov <anatol.pomozov at gmail.com>
+# Contributor: Gordian Edenhofer <gordian.edenhofer at gmail.com>
+# Contributor: Troy Engel <troyengel+arch at gmail.com>
+
+pkgbase=bcc
+pkgname=('bcc' 'bcc-tools' 'python-bcc')
+pkgver=0.16.0
+pkgrel=2
+pkgdesc='BPF Compiler Collection'
+arch=('x86_64')
+url='https://github.com/iovisor/bcc'
+license=('Apache')
+makedepends=('cmake' 'clang' 'llvm' 'flex' 'bison' 'python')
+checkdepends=('netperf' 'iperf')
+source=("bcc-$pkgver.tar.gz"::"https://github.com/iovisor/bcc/releases/download/v$pkgver/bcc-src-with-submodule.tar.gz")
+sha512sums=('ec2eec46ef45e96a269fe252de85734e12182bac839c7ee958852c6e7f4935b86f83536d6fd127933549f521d9b7af440544207818d5bd72a94567d41c6f3b75')
+
+build() {
+ mkdir -p bcc/build
+ cd bcc/build
+
+ # The python version is irrelevant at this stage
+ cmake -DREVISION=$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=/usr/lib ..
+
+ make
+}
+
+package_bcc() {
+ pkgdesc='BPF Compiler Collection - C library and examples'
+ depends=('clang' 'libelf')
+ optdepends=('linux-headers: build modules against the Arch kernel'
+ 'linux-lts-headers: build modules against the LTS kernel'
+ 'linux-zen-headers: build modules against the ZEN kernel'
+ 'linux-hardened-headers: build modules against the HARDENED kernel'
+ 'bcc-tools: Python utilites using the BCC library'
+ 'python-bcc: Python 3 bindings for BCC')
+ provides=('bcc' 'libbcc')
+
+ cd bcc/build
+
+ # Install the kitchen sink
+ make DESTDIR="$pkgdir" install
+
+ # These go in a split package python*-bcc
+ rm -rf "$pkgdir"/usr/lib/python*
+
+ # These go in a split package bcc-tools
+ rm -rf "$pkgdir"/usr/share/bcc/{tools,man}
+}
+
+package_bcc-tools() {
+ pkgdesc='BPF Compiler Collection - Tools'
+ arch=('any')
+ depends=('bcc' 'libedit' 'ethtool')
+ optdepends=(
+ 'python-bcc: Python 3 bindings for BCC'
+ 'luajit: Lua bindings for BCC'
+ )
+
+ cd bcc/build
+
+ make -C tools DESTDIR="$pkgdir" install
+ make -C man DESTDIR="$pkgdir" install
+}
+
+package_python-bcc() {
+ pkgdesc='BPF Compiler Collection - Python 3 bindings'
+ arch=('any')
+ depends=('bcc' 'python')
+ optdepends=(
+ 'python-netaddr: Network address representation and manipulation'
+ 'python-pyroute2: Netlink and Linux network configuration'
+ )
+
+ cd bcc/build
+
+ # Force a quick python3 binding build (C library is already built)
+ cmake -DREVISION=$pkgver \
+ -DPYTHON_CMD="python" \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=/usr/lib ..
+ make -C "src/python"
+
+ # Install just those bindings
+ make -C "src/python" DESTDIR="$pkgdir" install
+}
Property changes on: bcc/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list