[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Monday, October 12, 2020 @ 15:05:54
  Author: archange
Revision: 723662

Addition of erlang22-nox to [community], for building CouchDB

Added:
  erlang22-nox/
  erlang22-nox/repos/
  erlang22-nox/trunk/
  erlang22-nox/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: erlang22-nox/trunk/PKGBUILD
===================================================================
--- erlang22-nox/trunk/PKGBUILD	                        (rev 0)
+++ erlang22-nox/trunk/PKGBUILD	2020-10-12 15:05:54 UTC (rev 723662)
@@ -0,0 +1,49 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Vesa Kaihlavirta <vesa at archlinux.org>
+# Contributor: Sarah Hay <sarahhay at mb.sympatico.ca>
+# Contributor: Tom Burdick <thomas.burdick at wrightwoodtech.com>
+# Contributor: Ricardo Catalinas Jiménez <jimenezrick at gmail.com>
+
+pkgname=erlang22-nox
+pkgver=22.3.4.11
+_docver=22.3
+pkgrel=1
+pkgdesc="General-purpose concurrent functional programming language (headless version)"
+arch=(x86_64)
+url="https://www.erlang.org/"
+license=(Apache)
+depends=(ncurses openssl)
+makedepends=(fop git java-environment libxslt lksctp-tools)
+conflicts=(erlang)
+optdepends=('erlang-unixodbc: database support'
+            'java-environment: for Java support'
+            'lksctp-tools: for SCTP support')
+options=(staticlibs)
+_tag=79da813b2e7629bf882476e6e0bf8bf0969e8fc5 # git rev-parse OTP-${pkgver}
+source=("git+https://github.com/erlang/otp.git#tag=${_tag}")
+sha256sums=(SKIP)
+
+prepare() {
+  cd otp
+  ./otp_build autoconf
+}
+
+build() {
+  cd otp
+  ./configure \
+    --prefix=/usr \
+    --enable-builtin-zlib \
+    --enable-smp-support
+  make
+}
+
+package() {
+  cd otp
+
+  make DESTDIR="$pkgdir" install
+
+  # License
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}