[arch-commits] Commit in libnfc/trunk (PKGBUILD)

[Bruno Pagani]

    Date: Monday, October 12, 2020 @ 23:06:39
  Author: archange
Revision: 723765

upgpkg: libnfc 1.8.0-1

Also fix FS#63164.

Modified:
  libnfc/trunk/PKGBUILD

----------+
 PKGBUILD |   52 +++++++++++++++++++++++-----------------------------
 1 file changed, 23 insertions(+), 29 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2020-10-12 22:39:38 UTC (rev 723764)
+++ PKGBUILD	2020-10-12 23:06:39 UTC (rev 723765)
@@ -4,44 +4,38 @@
 # Contributor: Andrej Gelenberg <andrej.gelenberg at udo dot edu>
 
 pkgname=libnfc
-pkgver=1.7.1+204+g4ae4cc8
-pkgrel=2
+pkgver=1.8.0
+pkgrel=1
 pkgdesc="Platform independent Near Field Communication (NFC) library"
-arch=('x86_64')
+arch=(x86_64)
 url="http://nfc-tools.org/"
-license=('LGPL3')
-depends=('libusb-compat' 'pcsclite')
-makedepends=('cmake' 'git')
+license=(LGPL3)
+depends=(libusb-compat pcsclite)
+makedepends=(cmake)
 optdepends=('acsccid: acr122_pcsc support')
-_commit=4ae4cc86f85dd7362e9f369ba2bff0ab258b1799 # Latest tested commit
-source=("git+https://github.com/nfc-tools/libnfc.git#commit=${_commit}")
-sha256sums=('SKIP')
+source=(https://github.com/nfc-tools/libnfc/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.bz2)
+sha256sums=('6d9ad31c86408711f0a60f05b1933101c7497683c2e0d8917d1611a3feba3dd5')
 
-pkgver() {
-    cd ${pkgname}
-    git describe --tags | sed 's/libnfc-//' |sed 's/-/+/g'
-}
-
 prepare() {
-    mkdir -p build
-    cd ${pkgname}
-    # Use uaccess 
-    sed -i "s|MODE=\"0664\", GROUP=\"plugdev\"|TAG+=\"uaccess\"|g" contrib/udev/93-pn53x.rules
+  # Use uaccess 
+  sed -i "s|MODE=\"0664\", GROUP=\"plugdev\"|TAG+=\"uaccess\"|g" ${pkgname}-${pkgver}/contrib/udev/93-pn53x.rules
+  mv ${pkgname}-${pkgver}/contrib/udev/{93,70}-pn53x.rules
 }
 
 build() {
-    cd build
-    cmake ../${pkgname} \
-        -DCMAKE_INSTALL_PREFIX=/usr \
-        -DLIBNFC_DRIVER_ACR122_PCSC=ON
-    make
+  cmake -B build -S ${pkgname}-${pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBNFC_DRIVER_PCSC=ON \
+    -DLIBNFC_DRIVER_ACR122_PCSC=ON \
+    -DLIBNFC_DRIVER_ACR122_USB=ON \
+    -DLIBNFC_DRIVER_PN53X_USB=ON
+  make -C build
 }
 
 package() {
-    cd build
-    make DESTDIR="${pkgdir}" install
-    cd ../${pkgname}
-    install -Dm644 libnfc.conf.sample -t "${pkgdir}"/etc/nfc/
-    install -Dm644 contrib/udev/93-pn53x.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
-    install -Dm644 contrib/linux/blacklist-libnfc.conf -t "$pkgdir"/etc/modprobe.d/
+  make -C build DESTDIR="${pkgdir}" install
+  cd ${pkgname}-${pkgver}
+  install -Dm644 libnfc.conf.sample -t "${pkgdir}"/etc/nfc/
+  install -Dm644 contrib/udev/70-pn53x.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
+  install -Dm644 contrib/linux/blacklist-libnfc.conf -t "${pkgdir}"/usr/lib/modprobe.d/
 }