[arch-commits] Commit in libunistring/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Friday, October 16, 2020 @ 18:56:09
  Author: anthraxx
Revision: 398452

archrelease: copy trunk to testing-x86_64

Added:
  libunistring/repos/testing-x86_64/
  libunistring/repos/testing-x86_64/PKGBUILD
    (from rev 398451, libunistring/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: libunistring/repos/testing-x86_64/PKGBUILD (from rev 398451, libunistring/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-10-16 18:56:09 UTC (rev 398452)
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Emmanuel 'guinness' Boudreault
+# Contributor: Patrick McCarty <pnorcks at gmail dot com>
+
+pkgname=libunistring
+pkgver=0.9.10
+pkgrel=3
+pkgdesc='Library for manipulating Unicode strings and C strings'
+url='https://www.gnu.org/software/libunistring/'
+arch=(x86_64)
+license=(GPL)
+depends=(glibc)
+provides=('libunistring.so')
+source=(https://ftp.gnu.org/gnu/$pkgname/${pkgname}-${pkgver}.tar.xz{,.sig})
+validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # Daiki Ueno <ueno at unixuser.org>
+sha256sums=('eb8fb2c3e4b6e2d336608377050892b54c3c983b646c561836550863003c05d7'
+            'SKIP')
+b2sums=('25d162d9d510cc35ad4209acceb9b06bcc0553b8ce56e94f8df12c4df64d91abfc4a9e15b50b5c8d5b9672939305a394a7e83f1892258defb7ae5ac2ccf79dfb'
+        'SKIP')
+
+prepare() {
+  cd $pkgname-$pkgver
+  # https://git.savannah.gnu.org/cgit/gnulib.git/commit/?id=cca32830b5
+  sed -i '/pragma weak pthread_create/d' tests/glthread/thread.h
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr
+  make
+}
+
+check() {
+  make -C $pkgname-$pkgver check
+}
+
+package() {
+  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
+}
+
+# vim: ts=2 sw=2 et: