[arch-commits] Commit in python-scipy/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Antonio Rojas]

    Date: Sunday, October 18, 2020 @ 10:08:00
  Author: arojas
Revision: 725874

archrelease: copy trunk to community-x86_64

Added:
  python-scipy/repos/community-x86_64/PKGBUILD
    (from rev 725873, python-scipy/trunk/PKGBUILD)
Deleted:
  python-scipy/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  102 ++++++++++++++++++++++++++-----------------------------------
 1 file changed, 45 insertions(+), 57 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-10-18 10:07:49 UTC (rev 725873)
+++ PKGBUILD	2020-10-18 10:08:00 UTC (rev 725874)
@@ -1,57 +0,0 @@
-# Contributor: Thomas Dziedzic < gostrc at gmail >
-# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
-# Contributor: Ray Rashif <schiv at archlinux.org>
-# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
-# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
-# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
-
-_name=scipy
-pkgname=python-scipy
-pkgver=1.5.2
-pkgrel=1
-pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
-arch=('x86_64')
-url="https://www.scipy.org/"
-license=('BSD')
-depends=('python-numpy')
-provides=('python3-scipy' 'scipy')
-makedepends=('gcc-fortran' 'python-setuptools' 'pybind11')
-checkdepends=('python-pytest')
-optdepends=('python-pillow: for image saving module')
-#source=("https://github.com/scipy/scipy/releases/download/v${pkgver}/scipy-${pkgver}.tar.xz")
-source=("https://pypi.python.org/packages/source/${_name:0:1}/${_name}/${_name}-${pkgver}.tar.gz")
-sha512sums=('45463df30a0f6270d9f4cf52235f31607904a6ae1375e12600e7f1ab2d27b1dc25a6211b49dceb71506be22c756890adaf9f81d9e6be7455def86c9caf0dc923')
-
-build() {
-  # required for gfortran
-  export LDFLAGS="-Wall -shared"
-
-  cd scipy-${pkgver}
-  python setup.py config_fc --fcompiler=gnu95 build
-}
-
-check() {
-  # we need to do a temp install so we can import scipy
-  # also, the tests must not be run from the scipy source directory
-  export LDFLAGS="-Wall -shared"
-
-  cd scipy-${pkgver}
-  python3 setup.py config_fc --fcompiler=gnu95 install \
-    --prefix=/usr --root=${srcdir}/test --optimize=1
-  export PYTHONPATH=${srcdir}/test/usr/lib/python3.8/site-packages
-  cd "${srcdir}"
-  python -c "from scipy import test; test('full')"
-}
-
-package() {
-  export LDFLAGS="-Wall -shared"
-
-  cd scipy-${pkgver}
-  python3 setup.py config_fc --fcompiler=gnu95 install \
-    --prefix=/usr --root="${pkgdir}" --optimize=1
-
-  install -Dm644 LICENSE.txt \
-    "${pkgdir}/usr/share/licenses/python-scipy/LICENSE"
-}
-
-# vim:set ts=2 sw=2 et:

Copied: python-scipy/repos/community-x86_64/PKGBUILD (from rev 725873, python-scipy/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-10-18 10:08:00 UTC (rev 725874)
@@ -0,0 +1,45 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+
+_name=scipy
+pkgname=python-scipy
+pkgver=1.5.3
+pkgrel=1
+pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
+arch=('x86_64')
+url="https://www.scipy.org/"
+license=(BSD)
+depends=(python-numpy)
+provides=(scipy)
+makedepends=(gcc-fortran python-setuptools pybind11)
+checkdepends=(python-pytest)
+optdepends=('python-pillow: for image saving module')
+source=("https://pypi.python.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz")
+sha256sums=('ddae76784574cc4c172f3d5edd7308be16078dd3b977e8746860c76c195fa707')
+
+build() {
+  cd scipy-${pkgver}
+  python setup.py config_fc build
+}
+
+check() {
+  cd scipy-${pkgver}
+  python setup.py config_fc install \
+    --prefix=/usr --root="$srcdir"/test --optimize=1
+  export PYTHONPATH="$srcdir"/test/usr/lib/python3.8/site-packages
+  cd ..
+  python -c "from scipy import test; test('full')"
+}
+
+package() {
+  cd scipy-$pkgver
+  python3 setup.py config_fc install \
+    --prefix=/usr --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+}