[arch-commits] Commit in composer/repos (testing-any testing-any/PKGBUILD)

[Pierre Schmitz]

    Date: Saturday, October 24, 2020 @ 16:12:45
  Author: pierre
Revision: 398776

archrelease: copy trunk to testing-any

Added:
  composer/repos/testing-any/
  composer/repos/testing-any/PKGBUILD
    (from rev 398775, composer/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: composer/repos/testing-any/PKGBUILD (from rev 398775, composer/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2020-10-24 16:12:45 UTC (rev 398776)
@@ -0,0 +1,53 @@
+# Maintainer: Pierre Schmitz <pierre at archlinux.de>
+
+pkgname=composer
+pkgver=2.0.0
+pkgrel=1
+pkgdesc="Dependency Manager for PHP"
+arch=('any')
+license=('MIT')
+url='https://getcomposer.org/'
+depends=('php' 'unzip')
+makedepends=('git')
+checkdepends=('php-intl')
+source=("${pkgname}::git+https://github.com/composer/composer.git#tag=${pkgver}"
+        "${pkgname}-${pkgver}.phar::https://getcomposer.org/download/${pkgver}/composer.phar")
+sha256sums=('SKIP'
+            '139657aa2b37867800292724145e3c4895f7755d845758b403dc329d17bdd285')
+COMPOSER_FLAGS="--ansi --no-interaction --no-progress --prefer-dist"
+
+prepare() {
+	cd "${srcdir}/${pkgname}"
+
+	php "${srcdir}/${pkgname}-${pkgver}.phar" install --no-dev ${COMPOSER_FLAGS}
+}
+
+build() {
+	cd "${srcdir}/${pkgname}"
+
+	php -d phar.readonly=Off bin/compile
+}
+
+check() {
+	cd "${srcdir}/${pkgname}"
+
+	# check if the upstream build and ours differ
+	diff -q ${srcdir}/${pkgname}-${pkgver}.phar composer.phar > /dev/null || msg2 "Upstream composer differs from ours"
+
+	# Install the dev dependencies to run the unit tests
+	bin/composer install ${COMPOSER_FLAGS}
+
+	bin/composer validate
+
+	git config --global user.email composer at example.com
+	git config --global user.name composer
+
+	php -d extension=intl vendor/bin/simple-phpunit
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm755 composer.phar "${pkgdir}/usr/bin/composer"
+}