[arch-commits] Commit in haskell-safe-exceptions/repos (2 files)

[Felix Yan]

    Date: Saturday, October 24, 2020 @ 21:34:44
  Author: felixonmars
Revision: 731785

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-safe-exceptions/repos/community-staging-x86_64/
  haskell-safe-exceptions/repos/community-staging-x86_64/PKGBUILD
    (from rev 731784, haskell-safe-exceptions/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-safe-exceptions/repos/community-staging-x86_64/PKGBUILD (from rev 731784, haskell-safe-exceptions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-24 21:34:44 UTC (rev 731785)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=safe-exceptions
+pkgname=haskell-safe-exceptions
+pkgver=0.1.7.1
+pkgrel=14
+pkgdesc="Safe, consistent, and easy exception handling"
+url="https://github.com/fpco/safe-exceptions"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc' 'haskell-hspec' 'haskell-void')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('9d3f97df6cae87eaf547e80f1d19d150bf850259dafacb59fcb143fd349dcff9c26e21971e5a2b68ab7b88b6ea88dff63cc3b571453d09afd4bd70805c3c3587')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}