[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Tuesday, October 27, 2020 @ 19:09:27
  Author: archange
Revision: 734865

Initial addition of nodejs-lts-fermium to [community]

Added:
  nodejs-lts-fermium/
  nodejs-lts-fermium/repos/
  nodejs-lts-fermium/trunk/
  nodejs-lts-fermium/trunk/PKGBUILD

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Added: nodejs-lts-fermium/trunk/PKGBUILD
===================================================================
--- nodejs-lts-fermium/trunk/PKGBUILD	                        (rev 0)
+++ nodejs-lts-fermium/trunk/PKGBUILD	2020-10-27 19:09:27 UTC (rev 734865)
@@ -0,0 +1,60 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=nodejs-lts-fermium
+pkgver=14.15.0
+pkgrel=1
+pkgdesc="Evented I/O for V8 javascript (LTS release: Fermium)"
+arch=(x86_64)
+url="https://nodejs.org/"
+license=(MIT)
+depends=(openssl zlib icu libuv c-ares brotli libnghttp2) # http-parser
+makedepends=(python procps-ng)
+optdepends=('npm: nodejs package manager')
+provides=("nodejs=$pkgver")
+conflicts=(nodejs)
+source=("${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz")
+# https://nodejs.org/download/release/latest-fermium/SHASUMS256.txt.asc
+sha256sums=(3736d8622e7b16913fa20ca3d696e3caa7fdaec30ccc1054d080d98c5c01fb3b)
+validpgpkeys=(C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8  # Myles Borins <mylesborins at google.com>
+              77984A986EBC2AA786BC0F66B01FBB92821C587A  # Gibson Fahnestock <gibfahn at gmail.com>
+              B9AE9905FFD7803F25714661B63B535A4C206CA9  # Evan Lucas <evanlucas at me.com>
+              DD8F2338BAE7501E3DD5AC78C273792F7D83545D  # Rod Vagg <rod at vagg.org>
+              B9E2F5981AA6E0CD28160D9FF13993A75599653C  # Shelley Vohr <shelley.vohr at gmail.com>
+              4ED778F539E3634C779C87C6D7062848A1AB005C  # Beth Griggs <Bethany.Griggs at uk.ibm.com>
+              C82FA3AE1CBEDC6BE46B9360C43CEC45C17AB93C) # Richard Lau <rlau at redhat.com>
+
+
+build() {
+  cd node-v${pkgver}
+
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --experimental-http-parser \
+    --shared-cares \
+    --shared-brotli \
+    --shared-nghttp2
+    # --shared-v8
+    # --shared-http-parser
+
+  make
+}
+
+check() {
+  cd node-v${pkgver}
+  # https://github.com/nodejs/node/issues/32765
+  sed -i '/\$(MAKE) -s test-doc/d' Makefile
+  make test
+}
+
+package() {
+  cd node-v${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
+